orbitParamsMenu.xs

if defined orbitParamsMenu { orbitParamsMenu:dispose. }
set orbitParamsMenu to gui(220, 160). Set orbitParamsMenu:x to -10. set orbitParamsMenu:y to 515. orbitParamsMenu:show.
{
    orbitParamsMenu:addlabel("Orbit Parameters").
    local opmm0 to orbitParamsMenu:addlabel("Apoapsis Height:").
    local opmm1 to orbitParamsMenu:addlabel("Time to Apoapsis: ").
    local opmm2 to orbitParamsMenu:addlabel("Periapsis Height:").
    local opmm3 to orbitParamsMenu:addlabel("Time To Periapsis:").
    local opmm4 to orbitParamsMenu:addlabel("Altitude (Terrain):").
    local opmm6 to orbitParamsMenu:addlabel("Vertical speed:").
    local opmm7 to orbitParamsMenu:addlabel("Ground speed: ").

    for txt in orbitParamsMenu:widgets { set txt:style:padding:v to 1. set txt:style:wordwrap to false. }

    local runcount to 0.
    local runmax to 8.
    local shipBounds to ship:bounds.
    on ship:parts:length { set shipBounds to ship:bounds. return true. }

    when true then {
        if(runcount < runmax)
        {
            set runcount to runcount + 1.
            return orbitParamsMenu:visible.
        }
        set runcount to 0.

        if eta:apoapsis < 3.4E38
        {
            set opmm0:text to "Apoapsis Height: " + round(apoapsis / 1000,2) + " km".
            set opmm1:text to "Time to Apoapsis: " + round(eta:apoapsis,2) + " s".
        }
        else
        {
            set opmm0:text to "Apoapsis Height: N/A".
            set opmm1:text to "(craft will orbit something else)".
        }
        set opmm2:text to "Periapsis Height: " + round(periapsis / 1000,2) + " km".
        set opmm3:text to "Time To Periapsis: " + round(eta:periapsis,2) + " s".
        set opmm4:text to "Altitude (Terrain): " + round(shipBounds:bottomaltradar,2) + " m".
        set opmm6:text to "Vertical speed: " + round(verticalspeed,2) + " m/s".
        set opmm7:text to "Ground speed: " + round(groundspeed,2) + " m/s".
        return orbitParamsMenu:visible.
    }
    clearscreen.
}