PKGBUILD

# Maintainer: Brad Fanella <cesura@archlinux.org>
# Contributor: Martin Wimpress <code@flexion.org>

pkgname=mate-netbook
pkgver=1.22.0
pkgrel=2
pkgdesc="A simple window management tool"
url="https://mate-desktop.org"
arch=('x86_64')
license=('GPL')
depends=('libfakekey' 'mate-panel')
makedepends=('intltool')
groups=('mate-extra')
conflicts=('mate-netbook-gtk3')
replaces=('mate-netbook-gtk3')
source=("https://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
        "001.maximus_fix_segmentation_fault.patch"
)

sha256sums=('14c0aea8f49c4613592f1da4a8bd3548cd6dd091bd760b15dd7364b6d2e6e19e'
            'a7ee3d70bdb4530f777419c80ec7f649ef2c08eaf9fa77d84bcea973b9ada154')

prepare() {
    	cd "${pkgname}-${pkgver}/maximus"
        patch --strip=1 < ../../001.maximus_fix_segmentation_fault.patch
}

build() {
    	cd "${pkgname}-${pkgver}"
    	./configure \
        	--prefix=/usr \
        	--libexec=/usr/lib/${pkgname} \
        	--sysconfdir=/etc
    	make
}

package() {
    	cd "${pkgname}-${pkgver}"
    	make DESTDIR="${pkgdir}" install
}