The Optimized Query

ВЫБРАТЬ
	Цены.Номенклатура	КАК Номенклатура,
	Цены.Цена			КАК Цена,
	Цены.Валюта			КАК Валюта,
	Цены.ТипЦен			КАК ТипЦен

ПОМЕСТИТЬ Цены1

ИЗ
	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
		&ДатаОкончания,
		ТипЦен = &ТипЦен1) КАК Цены
;

ВЫБРАТЬ
	Цены.Номенклатура	КАК Номенклатура,
	Цены.Цена			КАК Цена,
	Цены.Валюта			КАК Валюта,
	Цены.ТипЦен			КАК ТипЦен

ПОМЕСТИТЬ Цены2

ИЗ
	РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
		&ДатаОкончания,
		ТипЦен = &ТипЦен2) КАК Цены
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	РБ.Счет															КАК Счет,
	ВЫРАЗИТЬ(РБ.Субконто3 КАК Справочник.Номенклатура).Наименование КАК НоменклатураНаименование,
	РБ.Субконто2													КАК СтавкаНДС,
	РБ.СуммаНачальныйОстаток										КАК НачальныйОстаток,
	РБ.СуммаОборот													КАК Оборот,
	РБ.СуммаКонечныйОстаток											КАК КонечныйОстаток,
	ЦеныТип1.Цена													КАК Цена1,
	ЦеныТип2.Цена													КАК Цена2,
	ЦеныТип1.Валюта.Наименование									КАК ВалютаЦены1,
	ЦеныТип2.Валюта.Наименование									КАК ВалютаЦены2
ИЗ
	РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&ДатаНачала, &ДатаОкончания, , , Счет В ИЕРАРХИИ (&Счет), , Организация = &Организация) КАК РБ

		ЛЕВОЕ СОЕДИНЕНИЕ Цены1 КАК ЦеныТип1
		ПО РБ.Субконто3 = ЦеныТип1.Номенклатура

		ЛЕВОЕ СОЕДИНЕНИЕ Цены2 КАК ЦеныТип2
		ПО РБ.Субконто3 = ЦеныТип2.Номенклатура

ИТОГИ
	СУММА(НачальныйОстаток),
	СУММА(Оборот),
	СУММА(КонечныйОстаток)
ПО
	Счет