user vars, mysql 5.6, attempt I

define print_user_var
    set $user_var=(user_var_entry*)($arg0)
    printf "@%s\n",$user_var->entry_name.m_str
    printf "----\n"
    printf "   Unsigned: %d\n", (int)$user_var->unsigned_flag
    printf "   Length  : %lu\n",(unsigned long)$user_var->m_length
    set $type=""
    if $user_var->m_type == 0
        printf "   Type    : STRING_RESULT\n"
        printf "   Value   : "
        print $user_var->m_ptr
    end
    if $user_var->m_type == 1
        printf "   Type    : REAL_RESULT\n"
        printf "   Value   : %f\n", *(double*)$user_var->m_ptr
    end
    if $user_var->m_type == 2
        printf "   Type    : INT_RESULT\n"
        if $user_var->m_ptr
          printf "   Value   : %d\n", *(long*)$user_var->m_ptr
        else
          printf "   Value   : null\n"
        end
            end
    if $user_var->m_type == 3
        printf "   Type    : ROW_RESULT\n"
        printf "   Value   : %x\n",$user_var->m_ptr
    end
    if $user_var->m_type == 4
        printf "   Type    : DECIMAL_RESULT\n"
        #printf "   Value   : todo: print this decimal value...\n"
        #if $user_var->m_ptr
        #   print *(my_decimal*)$user_var->m_ptr
        #   print "\n"
        #else
        #   printf "   Value   : null\n"
        #end
    end
end

document print_user_var
    print_user_var: Prints the given (user_var_entry*) pointer
end

define print_user_vars56
    set $thd=(THD*)($arg0)
    set $user_vars=$thd->user_vars
    set $records=$user_vars.records
    set $array = (DYNAMIC_ARRAY) $user_vars.array
    printf "------------------------------\n"
    printf " User Variables               \n"
    printf "------------------------------\n"
    printf "Total Variables     : %lu\n\n",(unsigned long)$records
    set $var_count = 0
        while($var_count < $records)
            set $hashlink = (struct st_hash_info*)((unsigned char*)($array.buffer) + sizeof(struct st_hash_info) * $var_count)
            set $user_var = (user_var_entry*)$hashlink->data
            print_user_var $user_var
            printf "\n\n"
            set $var_count=$var_count + 1
        end
end



document print_user_vars56
    print_user_vars56: Prints user variables associated with the given thd object
end