backupper_savekey

@echo off

reg query "HKU\S-1-5-19" >nul 2>&1 || (
  echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
  echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
  "%temp%\getadmin.vbs"
  del "%temp%\getadmin.vbs" >nul 2>&1
  exit /b
)

set regkeyX64=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion
set regkeyX86=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion
set regpathX64="%windir%\SysWOW64\winsevr.dat"
set regpathX86="%windir%\System32\winsevr.dat"
set regpath2X64="%%PROGRAMFILES(x86)%%\AOMEI Backupper\AmCore.dll"
set regpath2X86="%%PROGRAMFILES%%\AOMEI Backupper\AmCore.dll"

if "%PROCESSOR_ARCHITECTURE%" equ "AMD64" (
  set regkey=%regkeyX64%
  set regpath=%regpathX64%
) else (
  set regkey=%regkeyX86%
  set regpath=%regpathX86%
)

set regvalue=ProgramData
set regfile=backupper_regfile.bin
set restore=backupper_restore.bat

reg query %regkey% /v %regvalue% | findstr /i "%regvalue%" >"%temp%\tmpreg.reg"
set /p tmp=<"%temp%\tmpreg.reg"
del "%temp%\tmpreg.reg" >nul 2>&1
set reghex=%tmp:~33%

copy %regpath% "%~dp0%regfile%" /y >nul 2>&1

echo @echo off>"%~dp0%restore%"
echo.>>"%~dp0%restore%"
echo reg query "HKU\S-1-5-19" ^>nul 2^>^&1 ^|^| ( >>"%~dp0%restore%"
echo   echo Set UAC = CreateObject^^("Shell.Application"^^) ^> "%%temp%%\getadmin.vbs" >>"%~dp0%restore%"
echo   echo UAC.ShellExecute "%%~s0", "", "", "runas", 1 ^>^> "%%temp%%\getadmin.vbs" >>"%~dp0%restore%"
echo   "%%temp%%\getadmin.vbs" >>"%~dp0%restore%"
echo   del "%%temp%%\getadmin.vbs" ^>nul 2^>^&1 >>"%~dp0%restore%"
echo   exit /b >>"%~dp0%restore%"
echo ) >>"%~dp0%restore%"
echo. >>"%~dp0%restore%"
echo set regkeyX64=%regkeyX64%>>"%~dp0%restore%"
echo set regkeyX86=%regkeyX86%>>"%~dp0%restore%"
echo set regpathX64=%regpathX64%>>"%~dp0%restore%"
echo set regpathX86=%regpathX86%>>"%~dp0%restore%"
echo set regpath2X64=%regpath2X64%>>"%~dp0%restore%"
echo set regpath2X86=%regpath2X86%>>"%~dp0%restore%"
echo. >>"%~dp0%restore%"
echo if "%%PROCESSOR_ARCHITECTURE%%" equ "AMD64" ( >>"%~dp0%restore%"
echo   set regkey=%%regkeyX64%%>>"%~dp0%restore%"
echo   set regpath=%%regpathX64%%>>"%~dp0%restore%"
echo   set regpath2=%%regpath2X64%%>>"%~dp0%restore%"
echo ) else ( >>"%~dp0%restore%"
echo   set regkey=%%regkeyX86%%>>"%~dp0%restore%"
echo   set regpath=%%regpathX86%%>>"%~dp0%restore%"
echo   set regpath2=%%regpath2X86%%>>"%~dp0%restore%"
echo ) >>"%~dp0%restore%"
echo. >>"%~dp0%restore%"
echo reg add %%regkey%% /v %regvalue% /f /t REG_BINARY /d %reghex%>>"%~dp0%restore%"
echo copy "%%~dp0%regfile%" %%regpath%% /y ^>nul 2^>^&1 >>"%~dp0%restore%"
echo copy "%%~dp0%regfile%" %%regpath2%% /y ^>nul 2^>^&1 >>"%~dp0%restore%"