# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Riley Trautman <asonix@tamu.edu>
# Contributor: Lamelos <lamelos@gmail.com>

pkgname=pantheon-mail-git
_pkgname=pantheon-mail
pkgver=r1.4f0c143
pkgrel=1
pkgdesc='The Pantheon Mail Client'
arch=('i686' 'x86_64')
url='https://github.com/elementary/mail'
license=('GPL3')
depends=('cairo' 'gcr' 'gdk-pixbuf2' 'glib2' 'glibc' 'gmime' 'gtk3'
         'libaccounts-glib' 'libcanberra' 'libgee' 'libgsignon-glib'
         'libsecret' 'libxml2' 'pango' 'sqlite' 'webkitgtk'
         'libgranite.so')
makedepends=('meson' 'git' 'gnome-doc-utils' 'gobject-introspection'
             'granite-git' 'intltool' 'vala')
provides=(${_pkgname})
conflicts=(${_pkgname})
replaces=('pantheon-mail-bzr')
source=('git+https://github.com/elementary/mail.git')
sha256sums=('SKIP')

pkgver() {
  cd ${srcdir}

  echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
  cd ${srcdir}

  meson _build mail \
    --buildtype release \
    --prefix '/usr'
  ninja -C _build
}

package() {
  cd ${srcdir}
  DESTDIR="${pkgdir}" ninja -C _build install
}

# vim: ts=2 sw=2 et: