Begin _AA_abode_amulet

; This script teleports the player to the abode once they equip the amulet.

; changes /abot

short OnPCEquip
short PCSkipEquip
short button
short state
float t1

if ( PCSkipEquip )
else
    set PCSkipEquip to 1  ; skip wearing item
endif

if ( OnPCEquip )
    set OnPCEquip to 0

    ; avoid doubling bug in case MCP fix is not installed
    Player->AddItem "ab01UniqueRing" 1
    Player->RemoveItem "ab01UniqueRing" 1

    set state to 1
endif

if ( state )
else
    return
endif

if ( state == 1 )
    if ( MenuMode )
        MenuTest 0  ; close Menu
    endif
    PlaySoundVP "spellmake success" 0.6 1.0
    set state to 2
    FadeOut 0.5
    return
endif

if ( state == 2 )
    set t1 to ( t1 + GetSecondsPassed )
    if ( t1 > 0.5 )
        set t1 to 0
        set state to 3
        player->PositionCell 8 58 126 0 "Apothecary's Abode"
    endif
    return
endif

set t1 to ( t1 + GetSecondsPassed )
if ( GetPCCell "Apothecary's Abode" )
    set state to 4
elseif ( t1 > 5 )           ; safety
    set state to 4
endif
if ( state == 4 )
    set t1 to 0
    set state to 0
    FadeIn 0.4  ; PositionCellshould do this already, bot only in exteriors it seems /abot
endif

end