PKGBUILD-ssvnc-nojava

# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Florian Knodt <adlerweb@adlerweb.info>
# Contributor: Jose Riha <jose 1711 gmail com>

pkgname=ssvnc-nojava
_pkgname=ssvnc
pkgver=1.0.30
pkgrel=6
pkgdesc="SSL/SSH VNC viewer no java"
arch=('i686' 'x86_64')
url="http://www.karlrunge.com/x11vnc/ssvnc.html"
license=('GPL')
groups=('network')
depends=('libjpeg>=7' 'libxaw' 'tk')
provides=(${_pkgname})
conflicts=(${_pkgname})
makedepends=('imake')
optdepends=('perl' 'xterm' 'smbclient' 'avahi' 'stunnel')
source=(http://ssvnc.sourceforge.net/dev/$_pkgname-$pkgver.src.tar.gz
https://sources.debian.org/data/main/s/ssvnc/1.0.29-4/debian/patches/openssl1.1.patch
https://sources.debian.org/data/main/s/ssvnc/1.0.29-4/debian/patches/auto-scale.patch)
md5sums=('33d7c2d22d80ed26803275a9a83ddbb5'
'6a119a5748a231f63c96044a2761845f'
'a6c612b9f85ff05ad7f5c7705bd8b4a1')

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  patch -p1 < "$srcdir/openssl1.1.patch"
  patch -p1 < "$srcdir/auto-scale.patch"
  sed -i '/wr_tool/s/\$(PREFIX)\/\$(LIB)\/\([^/]*$\)/\/usr\/lib\/ssvnc\/\1/' Makefile
  make JSRC= config
  make JSRC= CCOPTIONS=-DTURBOVNC EXTRA_LIBRARIES='-L/usr/lib -Xlinker --rpath=/usr/lib -lturbojpeg' all
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make JSRC= PREFIX="$pkgdir/usr" MANDIR="share/man" install
}

# vim:set ts=2 sw=2 et: