task TStageScene(let pathReplay)
{
	let dirCurrent = GetCurrentScriptDirectory();
	let dirModule = GetModuleDirectory();
	let pathMainScript = dirCurrent ~ "stagetest.txt";
	let pathPlayer = dirModule ~ "script/player/newplayer3/player2.txt";

	//--------------------------------

	RenderSceneToTransitionTexture();
	TTransition();

	//--------------------------------

	InitializeStageScene();
	if(length(pathReplay) > 0)
	{
		SetStageReplayFile(pathReplay);
	}

	//--------------------------------

	let indexStage = 1;
	SetStageIndex(indexStage);
	SetStageMainScript(pathMainScript);
	SetStagePlayerScript(pathPlayer);
	StartStageScene();

	//--------------------------------

	loop
	{
		//--------------------------------

		if(GetVirtualKeyState(VK_PAUSE) == KEY_PUSH)
		{
			let resPause = RunPauseScene();
			alternative(resPause)
			case(RESULT_RETRY)
			{

				if(!IsReplay())
				{
					//リトライ
					TerminateStageScene();
					TStageScene("");
					return;
				}
			}
			case(RESULT_END)
			{

				TerminateStageScene();
			}
		}

		if(!IsReplay() && GetKeyState(KEY_BACK) == KEY_PUSH)
		{

			TerminateStageScene();
			TStageScene("");
			return;
		}

		//--------------------------------

		let stgSceneState = GetStageSceneState();
		if(stgSceneState == STAGE_STATE_FINISHED)
		{

			let stageResult = GetStageSceneResult();
			alternative(stageResult)
			case(STAGE_RESULT_CLEARED)
			{

				if(indexStage == 2)
				{
					//ステージ2をクリアした場合は終了
					TEndScene();
					break;
				}
				else
				{
					//次のステージへ遷移
					indexStage++;
					SetStageIndex(indexStage);
					SetStageMainScript(pathMainScript); //ひとまず同じステージ...
					SetStagePlayerScript(pathPlayer);
					StartStageScene();
					TTransition();
				}
			}
			case(STAGE_RESULT_PLAYER_DOWN)
			{
				//自機残機0
				TEndScene();
				break;
			}
			case(STAGE_RESULT_BREAK_OFF)
			{
				//ステージ途中終了
				//一時停止中の終了
				TTitleScene();
				break;
			}
		}
		yield;
	}

	TTransition();
}