freetype2-ubuntu precise

# Mantainer: Diego Principe <cdprincipeat gmaildot com>
# Contributor: Matjaz Mozetic <rationalperseus@gmail.com>
# Contributor: Tevin Zhang <mail2tevin {at} gmail {dot} com>
# Contributor: Andrea Fagiani <andfagiani {at} gmail {dot} com>
# Contributor: Paul Bredbury <brebs@sent.com>
# Contributor: Biru Ionut <biru.ionut at gmail.com>

# Installation order:  freetype2-ubuntu fontconfig-ubuntu libxft-ubuntu cairo-ubuntu
pkgname=freetype2-ubuntu
pkgver=2.5.0.1
_ubver=2.4.8-1
_ubrel=precise
pkgrel=99
pkgdesc="TrueType font rendering library, with Ubuntu's LCD rendering patches"
arch=('i686' 'x86_64')
url="https://launchpad.net/ubuntu/+source/freetype"
license=('GPL')
depends=('zlib' 'bzip2' 'sh')
conflicts=('freetype2' 'freetype2-cleartype' 'freetype2-lcd')
provides=("freetype2=$pkgver")
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2
        https://launchpad.net/ubuntu/$_ubrel/+source/freetype/$_ubver/+files/freetype_$_ubver.diff.gz
        freetype-2.2.1-enable-valid.patch
        freetype-2.3.0-enable-spr.patch
        freetype-2.4.11-enable-sph.patch)

md5sums=('c72e9010b1d986d556fc0b2b5fcbf31a'
         '97a1f13bcf4c5e5a9fc32795fcc72c44'
         '214119610444c9b02766ccee5e220680'
         '38765b5cc604179bf3afe33671d8ae37'
         '4d4a0caad7aa5e09bea0719cd80681bf')

prepare() {
  cd "${srcdir}/freetype-${pkgver}"

  # Patch from ubuntu
  patch -Np1 -i $srcdir/freetype_$_ubver.diff


  sed -e "s/-p[0-9]\|.*otvalid\.patch//g" \
      -i debian/patches-freetype/series

  sed -e 's/ src/ a\/src/g' \
      -e '/^Index.*fbase.c/,/EOF/d' \
      -i debian/patches-freetype/freetype-2.1.7-backwards.compat.patch

  for _f in $(cat debian/patches-freetype/series) ; do
    patch -Np1 -i debian/patches-freetype/$_f
  done

  # Patches from arch trunkcat debian/patches-freetype/series
  patch -Np1 -i "${srcdir}/freetype-2.2.1-enable-valid.patch"
#  patch -Np1 -i "${srcdir}/freetype-2.3.0-enable-spr.patch"
  # Disabled for now due to resistance
  # Kept here for easier rebuilds via ABS
  # https://bugs.archlinux.org/task/35274
  #patch -Np1 -i "${srcdir}/freetype-2.4.11-enable-sph.patch"
}

build() {
  cd ${srcdir}/freetype-${pkgver}

  # PNG support is useless if FT_CONFIG_OPTION_USE_PNG is disabled
  ./configure --prefix=/usr --disable-static \
    --without-png

  make
}

check() {
  cd "${srcdir}/freetype-${pkgver}"
  make -k check
}

package() {
  cd ${srcdir}/freetype-${pkgver}
  make DESTDIR=${pkgdir} install
}