apply plugin: 'java'
apply plugin: 'maven-publish'

dependencies {
    compile 'javax.json:javax.json-api:1.0'
    compile 'org.glassfish:javax.json:1.0.4'
    testCompile 'junit:junit:4.11'
    compile group: 'commons-codec', name: 'commons-codec', version: '1.10'
}

task sourceJar(type: Jar, dependsOn: classes) {
    from sourceSets.main.allJava
}

task javaDocJar(type: Jar, dependsOn: javadoc) {
    from javadoc.destinationDir
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId project.artifactId

            from components.java

            artifact sourceJar {
                classifier "sources"
            }

            artifact javaDocJar {
                classifier "javadoc"
            }
        }
    }

    repositories {
        maven {
            def optionalSnapshot = project.version.endsWith('-SNAPSHOT') ? "-snapshots" : ""
            url "http://repoproxy.idainfront.se/repository/internal${optionalSnapshot}/"
            credentials {
                def console = System.console()
                if (console) {
                    username = console.readLine('> Please enter your username: ')
                    password = console.readPassword('> Please enter your password: ')
                } else {
                    logger.error "Cannot get console."
                }
            }
        }
    }
}