cone shader

Shader "Unlit/DangerOverlay"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_Color ("Color", Color) = (1,1,1,1)
		_Stencil("Stencil ID", Float) = 0
		_SpecularAmount("Specular Amount", Float) = 1
		_AmbientAmount("Ambient Amount", Float) = .4
	}
	SubShader
	{
		Tags {
			"RenderType"="Transparent"
			"Queue"="Transparent"
			"LightMode"="ForwardBase"
		}
		LOD 100

		Pass
		{
			Stencil {
				Ref [_Stencil]
				Comp Always
				Pass Replace
				ZFail Replace
			}
			Cull Back
			Blend SrcAlpha OneMinusSrcAlpha

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"
			#include "UnityLightingCommon.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
				float3 normal : NORMAL;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
				float4 diff : COLOR0;
			};

			sampler2D _MainTex;

			float4 _MainTex_ST;
			float4 _Color;
			float _SpecularAmount;
			float _AmbientAmount;

			v2f vert(appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);

				half3 worldNormal = UnityObjectToWorldNormal(v.normal);
				half nl = max(0, dot(worldNormal * 2, _WorldSpaceLightPos0.xyz));
				o.diff = nl * nl *  _LightColor0;

				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv) * _Color * 1.25 * i.diff + _Color * _AmbientAmount;
				col.a = _Color.a;
				return col;
			}
			ENDCG
		}

		Pass
		{
			Stencil {
				Ref [_Stencil]
				Comp NotEqual
			}
			Cull Front
			Blend SrcAlpha OneMinusSrcAlpha
			ZTest Always

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;
			float4 _Color;

			v2f vert(appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv) * _Color;
				col.a *= .35;
				return col;
			}
			ENDCG
		}
	}
}