cairo-ubuntu 1.13.1

# Maintainer: Ner0
# Contributor: Tevin Zhang <mail2tevin {at} gmail {dot} com>
# Contributor: Paul Bredbury <brebs@sent.com>
# Contributor: Biru Ionut <biru.ionut at gmail.com>
# Contributor: Andrea Fagiani <andfagiani {at} gmail {dot} com>

# Installation order:  freetype2-ubuntu fontconfig-ubuntu libxft-ubuntu cairo-ubuntu
pkgname=cairo-ubuntu
pkgver=1.13
_ubver=$pkgver-0ubuntu20140204
pkgrel=1
pkgdesc="Cairo vector graphics library, with Ubuntu's LCD rendering patches"
arch=('i686' 'x86_64')
url="http://cairographics.org/"
license=('LGPL' 'MPL')
depends=('libpng' 'libxrender' 'libxext' 'fontconfig' 'pixman>=0.28.0' 'glib2' 'mesa>=9.1' 'sh' 'lzo2')
makedepends=('mesa>=9.1' 'librsvg' 'gtk2' 'poppler-glib')
provides=("cairo=$pkgver" "cairo-tee=$pkgver")
conflicts=('cairo' 'cairo-cleartype' 'cairo-lcd' 'cairo-tee' 'cairo-xeffects')
options=('!libtool')
source=(https://launchpad.net/ubuntu/+archive/primary/+files/cairo_1.13.0%7E20140204.orig.tar.xz
        https://launchpad.net/ubuntu/+archive/primary/+files/cairo_1.13.0%7E20140204-0ubuntu1.debian.tar.gz
        cairo-respect-fontconfig.patch)

md5sums=('5f27b0b8179b113c1df6ba48fbc6c39b'
         'b986adc197f89875efbcbbb204ed4a0c'
         '79f7c141c49f3d65ab308cc706d50914')

build() {
  cd cairo-$pkgver.$pkgrel

  for _f in $(cat "$srcdir/debian/patches/series" | grep -v '#') ; do
    patch -Np1 -i "$srcdir/debian/patches/$_f"
  done

  patch -Np1 -i "$srcdir/cairo-respect-fontconfig.patch"

  autoreconf -vfi
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --disable-static \
    --enable-tee \
    --enable-gl \
    --enable-egl \
    --enable-svg \
    --enable-ps \
    --enable-pdf \
    --enable-gobject
  make
}

package() {
  cd cairo-$pkgver.$pkgrel
  make DESTDIR="$pkgdir" install
}