ArrayPlot[Table[x*y, {x, 4}, {y, 20}], Mesh -> True, ImageSize -> 1 -> 25]

(ArrayPlot[{#}, Mesh -> True, ImageSize -> 1 -> 25]) & /@ Table[x*y, {x, 4}, {y, 20}] // TableForm

tab = Table[x*y, {x, 4}, {y, 20}];
GraphicsGrid[Table[g = (Max[tab] - tab[[i, j]])/Max[tab];
    Graphics[{RGBColor[g, g, g], EdgeForm[Directive[Black]], Rectangle[]}],
        {i, 1, 4}, {j, 1, 20}], Spacings -> {20, 200}, ImageSize -> 600]

ArrayPlot[Table[x y, {x, 4}, {y, 20}],
  Mesh -> True,
  ImageSize -> 1 -> 25,
  MeshStyle -> {{White, Thickness[0.02]}, {White, Thickness[0.02]}}]

Clear[spacedArray]
spacedArray[data_?MatrixQ] := Block[
  {values, rectangle, range},
  {values, rectangle, range} = First@Cases[
     ArrayPlot[data, Mesh -> True],
     Raster[values_, rectangle_, range_] :> {values, rectangle, range},
     Infinity
   ];
  rectangle[[2, 2]] = rectangle[[2, 2]]/First@Dimensions[values];
  Column[
   Graphics[Raster[{#}, rectangle, range], ImageSize -> 1 -> 25] & /@ values
  ]
]

spacedArray[Table[x*y, {x, 4}, {y, 20}]]

spacedArray[Table[x*y, {x, 5}, {y, 10}]]

table = Table[x*y, {x, 4}, {y, 20}];
data = (1 - table/Max[table]);

Column[ListDensityPlot[{#, #}, InterpolationOrder -> {0, 0},
  ColorFunctionScaling -> False, ColorFunction -> GrayLevel,
  AspectRatio -> 1/20, Mesh -> All,
  MeshStyle -> Directive[Antialiasing -> False, GrayLevel[-1 + GoldenRatio]],
  Frame -> False, ImageSize -> 1 -> 40] & /@ data, Spacings -> 1]