function main(string _sPilotName)
{
    variable index:item MyDroneBayCargo
    variable iterator MyDroneBayCargo_Iterator
    variable index:int64 _inCombatDrones
    variable index:int64 _inActiveDrones

    if ${_sPilotName.Equal[""]} || ${_sPilotName.Equal[NULL]}
    {
        echo ${Time}: ERROR: You must supply a pilot name to assign drones to.
        return
    }

    ;//Check to see if we have active drones already.
    Me:GetActiveDroneIDs[_inActiveDrones]

    if ${_inActiveDrones.Used} == 0
    {
        ;//We do not have active drones in space so we should launch combat drones.
        MyShip:GetDrones[MyDroneBayCargo]
        MyDroneBayCargo:GetIterator[MyDroneBayCargo_Iterator]

        if ${MyDroneBayCargo_Iterator:First(exists)}
        {
            do
            {
                if ${MyDroneBayCargo_Iterator.Value.GroupID} == 100 && ${_inCombatDrones.Used} < 5
                    _inCombatDrones:Insert[${MyDroneBayCargo_Iterator.Value.ID}]
            }
            while ${MyDroneBayCargo_Iterator:Next(exists)}

            EVE:LaunchDrones[_inCombatDrones]
        }

        wait 20

        Me:GetActiveDroneIDs[_inActiveDrones]
    }

    ;//Assign our drones to the desired pilot.
    Eve:DronesAssist[_inActiveDrones,${Local["${_sPilotName}"].ID}]

    wait 20
}