eclipse-eclipsecolortheme 0.13.0 - PKGBUILD

# Maintainer: Jesús Jerez <jerezmoreno@gmail.com>
# Contributor: Jesús Jerez <jerezmoreno@gmail.com>
pkgname=eclipse-eclipsecolortheme
pkgver=0.13.0
_pkgdate="201311210852"
pkgrel=1
pkgdesc="Eclipse Color Theme"
url="http://www.eclipsecolorthemes.org"
license=("EPL/1.0")
arch=('any')
depends=('eclipse')
makedepends=('unzip')
noextract=("com.github.eclipsecolortheme_${pkgver}.${_pkgdate}.jar" "com.github.eclipsecolortheme.feature_${pkgver}.${_pkgdate}.jar")
source=(
        "http://eclipse-color-theme.github.com/update/features/com.github.eclipsecolortheme.feature_${pkgver}.${_pkgdate}.jar"
        "http://eclipse-color-theme.github.com/update/plugins/com.github.eclipsecolortheme_${pkgver}.${_pkgdate}.jar"
        )
md5sums=('d20e63e4e623311f8995064bed9e1872'
         'b7c0b7036faae8b5493b28f554302dc7')

package() {
    _dest="${pkgdir}"/usr/share/eclipse/dropins/${pkgname/eclipse-}/eclipse

    mkdir {plugins,features}
    cp com.github.eclipsecolortheme_${pkgver}.${_pkgdate}.jar plugins/
    cp com.github.eclipsecolortheme.feature_${pkgver}.${_pkgdate}.jar features/

    # Features
    find features -type f | while read _feature ; do
        if [[ ${_feature} =~ (.*\.jar$) ]] ; then
            install -dm755 "${_dest}"/${_feature%*.jar}
            cd "${_dest}"/${_feature/.jar}
            jar xf "${srcdir}/${_feature}" || return 1
        else
            install -Dm644 ${_feature} "${_dest}/${_feature}"
        fi
    done

    # Plugins
    find plugins -type f | while read _plugin ; do
        install -Dm644 ${_plugin} "${_dest}/${_plugin}"
    done
}