0 = [EAST, 5, "MOVE", "2", "1"] spawn {
   private _cacheGroup = true;

   private _side = param [0, EAST];
   private _count = param [1, 2 + floor random 4];
   private _GAIA_action = param [2, "MOVE"];
   private _ZONE = param [3, "1"];
   private _TARGETZONE = param [4, _zone];

   private _classnames = [];
   private _mygroup = [];
   private _markerpos = getMarkerpos _zone;
   private _markersize = if (((getMarkerSize _zone) select 0) > ((getMarkerSize _zone) select 1)) then {(getMarkerSize _zone) select 0} else {(getMarkerSize _zone) select 1};
   private ["_spawnpos", "_faction"];
   for "_i" from 1 to _count do {
      switch (_side) do {
         case WEST: {_faction = selectrandom ["BLU_F","BLU_G_F","BLU_T_F","BLU_CTRG_F"]};
         case EAST: {_faction = selectrandom ["OPF_F","OPF_G_F","OPF_T_F"]};
         default    {_faction = selectrandom ["IND_F","IND_G_F","IND_C_F"]};
      };
      _spawnpos = [(_markerpos select 0) - random _markersize + random _markersize, (_markerpos select 1) - random _markersize + random _markersize, _markerpos select 2];
      while {!(_spawnpos inArea _zone)} do {
         _spawnpos = [(_markerpos select 0) - random _markersize + random _markersize, (_markerpos select 1) - random _markersize + random _markersize, _markerpos select 2];
      };
      _spawnPos = [_spawnPos, 0, 100, 2, 0, 20, 0] call BIS_fnc_findSafePos;
      { if ((configName _x) isKindoF "CAManBase") then {_classnames pushback (configName _x)};
      } forEach ("getText (_x >> 'faction') == _faction" configClasses (configfile >> "CfgVehicles"));
      _mygroup resize (3 + floor random 5);
      _mygroup = _mygroup apply {selectrandom _classnames};
      _Group = [_spawnPos, _side, _myGroup] call BIS_fnc_spawnGroup;
      _Group setVariable ["GAIA_ZONE_INTEND",[_TARGETZONE, _GAIA_action], false];
      if (_cacheGroup) then {_group setVariable ["mcc_gaia_cache", true, true]};
      sleep 0.3;
   };
};