Equinox Sleep Spam and Melee Spin Attack

; Warframe Equinox Sleep Spam and Melee spinning attack

; Bind the skill you want to spam to Insert (in this case Sleep) to make the script work.
; When script is loaded, press Pause twice to start the Sleep-spam Loop.



#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.


; The Spin Attack button you want to use
SpinAtkButton = XButton2

; Your Melee Attack button in-game
MeleeButton = XButton1

; Your Crouch button in-game
Crouch = LCtrl

SetKeyDelay, 10, 10
AtkWait = 300
MiniWait = 25
ToolTipOnScreenTime = 2000
StartStop2 = 0
Spam2Btn = Insert
SpamSleep = 200
KeepSpamming = false


#IfWinActive ahk_exe Warframe.x64.exe

Hotkey, %SpinAtkButton%, SpinA
Return

SpinA:
    While GetKeyState(SpinAtkButton, "P") {

        ; Spin attack for normal melee mode with Melee Attack button
        Send {%Crouch% Down}
        Sleep, %MiniWait%
        Send {%MeleeButton%}
        Sleep, %MiniWait%
        Send {%Crouch% Up}
        Sleep, %AtkWait%
    }
Return


; This part keeps spamming Spam2Btn (Insert by default) when Pause is pressed, and stops when you press Pause again. Rebind if necessary to another key.
#MaxThreadsPerHotkey 3
Pause::
    #MaxThreadsPerHotkey 1
    ; If loop is running, a button press will trigger the loop in other thread to end
    If KeepSpamming
    {
        KeepSpamming := false
        Return
    }


    ; Initiate the loop to run
    KeepSpamming := true
    Loop
    {
        ; Alt+Tab (usually) stops the loop. If you press it fast, it might not.
        if (GetKeyState("LAlt", "P") && GetKeyState("Tab", "P"))
        {
            Break
        }


        ; Shift will pause the Loop, so you can sprint. Release Shift to continue the Loop.
        While GetKeyState("LShift", "P")
        {
            Keywait, LShift
        }


        ; Spam "Spam2Btn" (Insert by default) every "SpamSleep" milliseconds (200 ms by default)
        Send {%Spam2Btn%}
        Sleep %SpamSleep%


        If Not KeepSpamming
            Break
    }

    ; Failsafe
    KeepSpamming := false
Return


Esc::
    If KeepSpamming
    {
        KeepSpamming := false
    }
    Send {Esc}
Return


; Increase delay (Shift + PageUp)
+PgUp::
    AtkWait += 25
    Tooltip, Delay: %AtkWait%ms
    SetTimer, RemoveToolTip, %ToolTipOnScreenTime%
Return


; Decrease delay  (Shift + PageDown)
+PgDn::
    AtkWait -= 25
    Tooltip, Delay: %AtkWait%ms
    SetTimer, RemoveToolTip, %ToolTipOnScreenTime%
Return


; Show timer and swings  (Shift + Home)
$+Home::
    Tooltip, Delay: %AtkWait%ms
    SetTimer, RemoveToolTip, %ToolTipOnScreenTime%
Return

#IfWinActive


RemoveToolTip:
    SetTimer, RemoveToolTip, Off
    ToolTip
Return