keepassx2-git

# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Michael Laß <bevan@bi-co.net>
# Contributor: Marat "Morion" Talipov <morion.self@gmail.com>

_pkgname=keepassx
pkgname=keepassx2-git
pkgver=r1281.1682ab9
pkgrel=1
pkgdesc="Cross platform password manager"
url="https://www.keepassx.org"
arch=('x86_64')
license=('GPL2' 'GPL3')
source=('git+https://github.com/keepassx/keepassx.git')
sha256sums=('SKIP')
validpgpkeys=('164C70512F7929476764AB56FE22C6FD83135D45') # Felix Geyer <felix@fobos.de>
depends=('qt5-base' 'qt5-tools' 'libgcrypt' 'zlib' 'libxi' 'libxtst' 'shared-mime-info')
makedepends=('git' 'intltool' 'cmake' 'optipng')
optdepends=('qt5-x11extras: For auto-type on X11')
conflicts=('keepassx2')
provides=('keepassx2')
options=('!emptydirs')

pkgver() {
  cd "${srcdir}/${_pkgname}"

  # Get the version number.
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${_pkgname}"
  mkdir -p build
  cd build
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DCMAKE_BUILD_TYPE=Release
  make
}

check() {
  cd "${srcdir}/${_pkgname}/build"
  make test
}


package() {
  cd "${srcdir}/${_pkgname}/build"
  make DESTDIR="${pkgdir}" install
  rename 'keepassx' 'keepassx2' "${pkgdir}"/usr/share/icons/hicolor/*/*/keepassx.png
}