_basename=libseccomp
pkgname=lib32-libseccomp
pkgver=2.4.1
pkgrel=2
pkgdesc='Enhanced seccomp library'
arch=('x86_64')
license=('LGPL2.1')
url="https://github.com/seccomp/libseccomp"
depends=('lib32-glibc')
checkdepends=('valgrind')
provides=('libseccomp.so')
source=(https://github.com/seccomp/${_basename}/releases/download/v${pkgver}/${_basename}-${pkgver}.tar.gz{,.asc})
sha256sums=('1ca3735249af66a1b2f762fe6e710fcc294ad7185f1cc961e5bd83f9988006e8'
            'SKIP')

build() {
  cd ${_basename}-${pkgver}

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  export LDFLAGS+=' -m32'

  ./configure \
      --prefix=/usr \
      --libdir=/usr/lib32 \
      --build=i686-pc-linux-gnu \

  make
}

check() {
  cd ${_basename}-${pkgver}
  make check
}

package() {
  cd ${_basename}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 CHANGELOG README.md -t "${pkgdir}/usr/share/doc/${pkgname}"

  rm -rf "${pkgdir}"/usr/share/man
  rm -rf "${pkgdir}"/usr/include

  cd "${pkgdir}"/usr/bin
  mv scmp_sys_resolver scmp_sys_resolver-32

}

# vim: ts=2 sw=2 et: