mars-shooter-git - with patch - AUR

# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
pkgname=mars-shooter-git
pkgver=20120724
pkgrel=1
pkgdesc="A ridiculous space shooter with nice graphics"
arch=(i686 x86_64)
url="http://mars-game.sourceforge.net/"
license=('GPL')
depends=('sfml' 'taglib' 'fribidi')
makedepends=('cmake' 'subversion')
provides=('mars-shooter')
conflicts=('mars-shooter')
source=(window.patch)
md5sums=(95b3390c426461ce09c67d3131d41240)

_gitroot=git://github.com/thelaui/M.A.R.S..git
_gitname=mars

build() {
  cd "$srcdir"
  msg "Connecting to GIT server...."

  if [[ -d "$_gitname" ]]; then
    cd "$_gitname" && git pull origin
    msg "The local files are updated."
  else
    git clone "$_gitroot" "$_gitname"
  fi

  msg "GIT checkout done or server timeout"
  msg "Starting build..."

  rm -rf "$srcdir/$_gitname-build"
  git clone "$srcdir/$_gitname" "$srcdir/$_gitname-build"

  cd "$srcdir"
  patch -u $_gitname-build/src/System/window.cpp window.patch
  cd "$srcdir/$_gitname-build"

  cmake .
  make
}

package() {
  cd "$srcdir/$_gitname-build"

  mkdir -p $pkgdir/usr/share/marsshooter
  mkdir -p $pkgdir/usr/bin/
  cp -r credits.txt data/* license.txt $pkgdir/usr/share/marsshooter
  cp mars $pkgdir/usr/bin/mars-shooter
  find $pkgdir -name *.svn | xargs rm -rf

  sed -i 's/Exec=.*/Exec=mars-shooter/g' resources/mars.desktop
  install -Dm644 resources/mars.desktop $pkgdir/usr/share/applications/mars.desktop
  install -Dm644 resources/mars.png $pkgdir/usr/share/pixmaps/mars.png
}