#NoEnv
SendMode Input
#SingleInstance Force
SetBatchLines -1

;---------------LOAD ITEMS---------------
IniRead, Items, items.ini
Sort, Items
Items := StrReplace(Items, "`n", "|")

Gui, +ToolWindow +HwndMainHWND
Gui, Font, S8, Verdana

Gui, Add, ListBox, vItem h186 gItemSubmit w100 Section, % Items
Gui, Add, Button, w45 gAdd section, Add
Gui, Add, Button, w45 gDelete ys, Delete

Gui, Add, Text, xs+110 ym w120, Stock Level
Gui, Add, Edit, vStock wp

Gui, Add, Text, wp, Location
Gui, Add, Edit, wp h121 vLocation

Gui, Add, Button,  wp gSave, Save

Gui, Show, , Inventory Manager by Joseph

Return

Add:
    InputBox , NewItem, , Please enter the item name, , 200, 130
    If ErrorLevel
        return
    IniWrite, 0, Items.ini, % NewItem, Stock
    IniWrite, Table # , Items.ini, % NewItem, Location

    reloadItems()

    MsgBox % NewItem " Added"
return

Delete:
    Gui, Submit, Nohide
    If !Item{
        MsgBox, Please select an item first!
        return
    }

    IniDelete, items.ini, % Item

    reloadItems()

    MsgBox % Item " Deleted"
Return

ItemSubmit:
    Gui, Submit, Nohide
    If !Item
        return

    IniRead, Stock, items.ini, % Item, stock
    GuiControl,,Stock, % Stock

    IniRead, Location, items.ini, % Item, Location
    GuiControl,,Location, % Location
Return

Save:
    Gui, Submit, Nohide
    If !Item{
        MsgBox, Please select an item first!
        return
    }

    IniWrite, % Stock, Items.ini, % Item, Stock
    IniWrite, % Location, Items.ini, % Item, Location
    Msgbox % Item " Saved"
Return

GuiClose:
GuiEscape:
    ExitApp
Return

reloadItems(){
    global
    IniRead, Items, items.ini
    Sort, Items
    Items := StrReplace(Items, "`n", "|")
    GuiControl,, Item, |
    GuiControl,, Item, % Items
}