#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#NoTrayIcon
#SingleInstance force
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

;Setup Browsers Group
GroupAdd, Browsers, ahk_class Chrome_WidgetWin_1
GroupAdd, Browsers, ahk_class ApplicationFrameWindow

;Three Tap
<#<^<+F22::
	Sleep 1

	MouseGetPos, , , id
	WinGetClass, class, ahk_id %id%
	if ( class = "Shell_TrayWnd" ){			; Send Middle-click if over Taskbar (for 7+ Taskbar Tweaker)
		Send, {MButton}
	}
	else if WinActive("ahk_class CabinetWClass") {
		Send, !{Up}
	}
	else if WinActive("ahk_exe foobar2000.exe") {
		Send, {Media_Play_Pause}
	}
	else {
		Send, {MButton}
	}
Return


;Three Swipe Up
<^<!1::
	Sleep 1
	if ( WinActive("ahk_group Browsers") or WinActive("ahk_class CabinetWClass") ) {
		Send, !{Right}			;{Browser_Forward}
	}
	else if WinActive("ahk_exe foobar2000.exe") {
		Send, {Media_Prev}
	}
Return


;Three Swipe Down
<^<!2::
	Sleep 1
	if ( WinActive("ahk_group Browsers") or WinActive("ahk_class CabinetWClass") ) {
		Send, !{Left}			;{Browser_Back}
	}
	else if WinActive("ahk_exe foobar2000.exe") {
		Send, {Media_Next}
	}
Return


;Three Swipe Left
<^<!3::
	Sleep 1
	if ( WinActive("ahk_group Browsers") or WinActive("ahk_class TfrmMyLifeMain") or WinActive("ahk_exe foobar2000.exe") ) {
		Send, ^+{Tab}
	}
Return


;Three Swipe Right
<^<!5::
	Sleep 1
	if ( WinActive("ahk_group Browsers") or WinActive("ahk_class TfrmMyLifeMain") or WinActive("ahk_exe foobar2000.exe") ) {
		Send, ^{Tab}
	}
Return


;Four Tap
<#<^<+F24::
	Sleep 1
		;if ( WinActive("ahk_group Browsers") or WinActive("ahk_exe foobar2000.exe") or WinActive("ahk_class CabinetWClass") ) {
	Send, ^w
Return

;Four Swipe Up
<^<!6::
	Sleep 1
	if WinActive("ahk_class WorkerW")
	{
		Send, #d
		if WinActive("ahk_class WorkerW")
		{
			Send, #{Tab}
		}
	}
	else if WinActive("ahk_class MultitaskingViewFrame")
	{
		Send, #^d
	}
	else
	{
		Send, #{Tab}
	}
Return

;Four Swipe Down
<^<!7::
	Sleep 1
	if WinActive("ahk_class WorkerW") {
		Sleep 0
	}
	else if WinActive("ahk_class MultitaskingViewFrame") {
		Send, #{Tab}
	}
	else {
		Send, #d
	}
Return