RSIBands v2.0 (BizkitBR req)

//
// @version 2
// @title RSIBands v2.0 (BizkitBR req)
// @author LazyBear
// List of all my indicators: http://bit.ly/1LQaPK8
//
study("RSI Bands [LazyBear]", shorttitle="RSIBANDS2_LB", overlay=true)
obLevel = input(70, title="RSI Overbought")
osLevel = input(30, title="RSI Oversold")
length = input(14, title="RSI Length")
src=close
ep = 2 * length - 1
auc = ema( max( src - src[1], 0 ), ep )
adc = ema( max( src[1] - src, 0 ), ep )
x1 = (length - 1) * ( adc * obLevel / (100-obLevel) - auc)
ub = iff( x1 >= 0, src + x1, src + x1 * (100-obLevel)/obLevel )
x2 = (length - 1) * ( adc * osLevel / (100-osLevel) - auc)
lb = iff( x2 >= 0, src + x2, src + x2 * (100-osLevel)/osLevel )
cent=avg(ub,lb)
ux=plot( ub, title="Resistance", color=red, linewidth=2)
lx=plot( lb, title="Support", color=green, linewidth=2)
mx=plot( cent, title="RSI Midline", color=gray, linewidth=1)
fill(ux, mx, green)
fill(lx, mx, red)

markOBOS=input(true, title="Mark OB/OS bars")
colorBars=input(false, title="Color bars based on region")

c_rgn = colorBars?((src>cent)?#7CFC00:#FF6347):na
c_obos=markOBOS?(((src>=ub) or (src<=lb)) ?fuchsia:c_rgn):c_rgn
barcolor(c_obos)