* IMPORTING IV_BANK_ACC_NUMBER TYPE ZWL_BANK_ACC_NUMBER Numer rachunku bankowego
* RETURNING RV_MASK            TYPE ZWL_MASK_VALUE  Wartość maski

METHOD get_mask.

    READ TABLE me->o_model->get_masks( ) INTO DATA(ls_mask) WITH KEY key = iv_bank_acc_number+2(8).
    IF sy-subrc = 0.
      rv_mask = ls_mask-value.
    ENDIF.

ENDMETHOD.


* IMPORTING IV_MASK             TYPE ZWL_MASK_VALUE Wartość maski
* IMPORTING IV_BANK_ACC_NUMBER  TYPE ZWL_BANK_ACC_NUMBER    Numer rachunku bankowego
* RETURNING RV_BANK_ACC_NUMBER  TYPE ZWL_BANK_ACC_NUMBER    Zamaskowany numer rachunku
* EXCEPTION ZCX_WL_TAXPAYER     Biała Lista: klasa wyjątków

METHOD mask_key.

    DATA(lv_mask) = iv_mask.
    DATA lv_masked_bank_acc_n LIKE iv_bank_acc_number.
    DATA(lv_char_for_mask) = me->get_file_char_for_mask( ).

    lv_masked_bank_acc_n = iv_mask.

    DO strlen( lv_masked_bank_acc_n ) TIMES.

      DATA(lv_index) = sy-index - 1.

      IF sy-index = 100.
        "Błąd podczas maskowania NRB &1.
        RAISE EXCEPTION TYPE zcx_wl_taxpayer MESSAGE ID c_msg_id TYPE 'E' NUMBER '002' WITH iv_bank_acc_number.
      ENDIF.

      IF lv_masked_bank_acc_n+lv_index(1) = lv_char_for_mask. "Default Y
        lv_masked_bank_acc_n+lv_index(1) = iv_bank_acc_number+lv_index(1).
      ENDIF.

    ENDDO.

    rv_bank_acc_number = lv_masked_bank_acc_n.

  ENDMETHOD.