Exemple Simple :
Affiche "Bonjour !"

Exemple avec une fonction :
->message {
    "Bonjour" !
}
évoque .message()

Exemple complexe :
.prototype=L'attaque des clones
.spécification=2.0
.auteur=cpc6128

énergie:nombre 1000
nom:texte

("Création de deux nouveaux prototypes ")
stormtrooper<<entité:énergie
jedi<<entité:énergie, nom

("création des instances vierges :")
prototype:stormtrooper
yoda:jedi

("********************************************")
("Méthodes fonctionnelles d'un stormtrooper :")
("********************************************")

prototype->attaquer {
        ("Le stormtrooper perd de l'energie quand il attaque")
        force:nombre 100

        mélange force
        .énergie = .énergie - force * 10
        retourne force
        }

prototype->perdre énergie {
        *point:nombre

        .énergie = .énergie - point
        retourne .énergie
}

prototype->vivant {
        si .énergie > 0 retourne vrai
        sinon retourne faux
}

("***********************************")
("Méthodes fonctionnelles d'un jedi :")
("***********************************")

yoda->frapper {
        *ennemi:stormtrooper
        force:nombre 500

        mélange force
        évoque ennemi.perdre énergie(force)
        retourne force
}

yoda->prendre coup {
        *point:nombre
        .énergie = .énergie - point
        retourne .énergie

yoda->respire encore {
        si .énergie > 0 retourne vrai
        sinon retourne faux
}


->principal {
        *prototype:stormtrooper
        *yoda:jedi
        armée:casier:stormtrooper vide
        taille armée:nombre 100
        vivants:nombre taille armée ("Nombre de stormtroopers encore vivants")

        prototype.énergie = 1000
        yoda.énergie = 1000

        ("On ajoute les clones du prototype dans l'armée :")
        pour chaque taille armée ajoute #prototype dans armée
        ("àààà l'attaaaqueeee !")
        tant que vivants > 0 {
            i:nombre
            pour i de 0 à taille armée - 1 {
                si armée{i}.vivant() = vrai {
                    dégât:nombre
                    efface tableau
                    "--> Attaque du stormtrooper n° " + i + " :" !
                    dégât vaut armée{i}.attaquer()
                    "    Il vient de faire une attaque de " + dégât + " points." !
                    "    Il reste " + yoda.prendre coup(dégât) + " énergie à " + yoda.nom !
                    si yoda.respire encore() = faux {
                        "    " + yoda.nom + " est mort. " !
                        "****L'alliance a perdu !" !
                        termine
                    }
                    "    " + yoda.nom + " répond en attaquant... " !
                    dégât = yoda.frapper(armée{i})
                    "    ...il vient de faire un attaque de " + dégât + " points." !
                    "    Le stormtrooper a maintenant " + (armée{i}).énergie + " points d'énergie." !
                    si armée{i}.vivant() = faux {
                        "    Le stormtrooper n° + " + i + " est mort !" !
                        décrémente vivants
                    }
                    attends 500 milliseconde
                }
            }
        }
        "    L'armée des clones est décimée !" !
        "****L'alliance a gagné !" !
}

("On exécute le programme :")
évoque .principal(prototype,yoda)