gold any% NSC connection warp

no, it isn't possible in less than 7 box names, so characters are spaced out to optimize movement

BOX 1 - 6
é d 2 é D 9 'v 7
é [ 'd H . 9
é h 'd H é g 'd
é H 'd 'v é é & 2
H é ] 'd ] é é 4
'l 'l 'l 'l 'd

BOX 14
p p p p 5 'm v 2 (the p p p bit is filler)

MUST MANIP 55552-55807 (D9) OR 63744-63999 (F9)

pick up coin case from above (IMPORTANT)
walk left 1, up 1, left 2
bellsprout cry
use coin case
walk down, left, up
talk to red (press A)

=== Sauce Code/Notes ===
; BOX 1 d8bf-d8c7
; é d 2 é D 9 'v 7
	ld [$f8a3], a ; make red appear
	ld [$ff83],a ; kill OAM DMA
	sub $fd ; $00 get $03
	db $50

; BOX 2 d8c8-d8d0
; é [ 'd H . 9
	ld [$d09e], a ; map group
	add a ; $03 get $06
	add sp, $ff ; actually decreases sp by 1. four pops + -1 = 3 pops + 1 inc from pre-2016 box names
	db $50

; BOX 3 d8d1-d8d9
; é h 'd H é g 'd
	ld [$d0a7], a ; x displacement
	add a ; $06 get $0c
	ld [$d0a6], a ; y displacement
	db $50

; BOX 4 d8da-d8e2
; é H 'd 'v é é & 2
	ld [$d087], a ; map height for connection warp
	sub $ea ; $0c get $22
	ld [$f8e9], a ; self modify for party count
	db $50

; BOX 5 d8e3-d8eb
; H é ] 'd ] é é 4
	add a ; $22 get $44
	ld [$d09f], a ; map number
	sbc a ; saves 3 cursor inputs over alternatives (xor a, sub a)
	ld [$faea], a ; party count
	db $50

; BOX 6 d8ec-d8f4
; 'l 'l 'l 'l 'd
	pop de ; first of four
	pop de ; second
	pop de ; third
	pop de ; fourth
	ret nc
	db $50

; BOX 14 (bootstrap) d934-d93c

; p p p p 5 'm v 2 (the p p p bit is filler)
	xor a
	xor a
	xor a
	xor a ; entry point
	ei ; 1/128 lol
	jp nc, $f8b5 ; jumps into safe code just before box 1 name (almost all nops, one ld bc, xxxx)

; d091 = wMapConnections
; try wMapWidth = 02

; map: 03:44

; ydisplacement = 0c
; xdisplacement = 06