SISTEMA: Base explosão de caixas ~Nyft

#include a_samp
#include pawn.cmd
#include YSI_Coding\y_va

/*

    * Sobre a include "y_va":

      - Não é necessário usá-la;
      - Só usei para não precisar formatar mensagens com argumentos;

*/

const MINUTES_FIX_ATM = 5;
const SECONDS_EXPLODE_ATM = 10;

static
    bool:ExplodedATM[MAX_PLAYERS];

enum E_ATM
{
    bool:E_ATM_FIXED,

    Float:E_ATM_X,
    Float:E_ATM_Y,
    Float:E_ATM_Z
};

static ATM_POSITIONS[][E_ATM] =
{
    {true, 129.3003, -68.0531, 1.5781},
    {true, 157.1488, -62.1891, 1.5781},
    {true, 172.4259, -62.2822, 1.5781}
};

main(){}

forward OnPlayerExplodeATM(playerid, id);
public OnPlayerExplodeATM(playerid, id)
{
    ATM_POSITIONS[id][E_ATM_FIXED] = false;
    SetTimerEx("OnFixATM", MINUTES_FIX_ATM * 60 * 1000, false, "i", id);
    va_SendClientMessage(playerid, -1, "* Caixa eletrônico %i explodido com sucesso.", id);
    return 1;
}

forward OnFixATM(id);
public OnFixATM(id)
{
    ATM_POSITIONS[id][E_ATM_FIXED] = true;
    va_SendClientMessageToAll(-1, "* O caixa eletrônico %i foi consertado com sucesso.", id);
    return 1;
}

GetClosestATMID(playerid, Float:radi = 2.0)
{
    for(new i; i < sizeof(ATM_POSITIONS); i++)
        if(IsPlayerInRangeOfPoint(playerid, radi, ATM_POSITIONS[i][E_ATM_X], ATM_POSITIONS[i][E_ATM_Y], ATM_POSITIONS[i][E_ATM_Z]))
            return i;

    return -1;
}

//

CMD:explodir(playerid)
{
    if(ExplodedATM[playerid])
        return SendClientMessage(playerid, -1, "* Você já explodiu um caixa eletrônico recentemente.");

    new id = -1;

    if((id = GetClosestATMID(playerid)) == -1)
        return SendClientMessage(playerid, -1, "* Você não está próximo de um caixa eletrônico.");

    if(!ATM_POSITIONS[id][E_ATM_FIXED])
        return SendClientMessage(playerid, -1, "* Esse caixa não está funcionando no momento.");

    ExplodedATM[playerid] = true;
    SetTimerEx("OnPlayerExplodeATM", SECONDS_EXPLODE_ATM * 1000, false, "ii", playerid, id);
    va_SendClientMessage(playerid, -1, "* Você começou a explodir o caixa eletrônico %i.", id);
    return 1;
}