Charters.ash

import DicsLibrary.ash

/*******************************************************\
*					That 70s Volcano
\*******************************************************/
void getTowerCoin() {
// Equips velvet items and grabs a volcoino
	if ( get_property_bool("_infernoDiscoVisited") )
		return;
	if ( outfit( "smooth velvet" ) ) {
		visit_url("place.php?whichplace=airport_hot&action=airport4_zone1");
		run_choice(7);
	}
	else
		print("Couldn't equip smooth velvet outfit","red");
}

void VolcanoQuest() {
// Takes and finishes the Volcano quest (from the mall if mallprices allow).
	if ( usesRemaining("_volcanoItemRedeemed") ) {
		int Volcoino = itemValue($item[Volcoino]);
		int [item] availableQuests;
		item cheapestItem,fuseChoiceNumber;
		boolean noAdventure, fusedFuse;

		void visitVolcanoBunker() {
			page = visit_url("place.php?whichplace=airport_hot&action=airport4_questhub");
		}

		int VolcanoQuestCost( item it ) {
			int qty = 1;
			switch (it) {
				case $item[smooth velvet bra]:
					qty = 3;
					break;
				case $item[New Age healing crystal]:
				case $item[gooey lava globs]:
					qty = 5;
					break;
				case $item[SMOOCH bracers]:
					qty = 15;
					it = $item[Superheated metal];
			}
			return itemValue(it) * qty;
		}

		if ( get_property_int("_volcanoItem1") == 0 )
			visitVolcanoBunker();

		for i from 1 to 3
			availableQuests[ to_item(get_property("_volcanoItem"+i)) ] = get_property_int("_volcanoItemCount"+i);

		foreach it,qty in availableQuests {
			if ( it.tradeable ) {
				StockUp(qty,it,Volcoino/qty/4,Volcoino/qty);
				noAdventure = true;
			}
			else if ( it == $item[SMOOCH bracers] ) {
				StockUp(15,$item[Superheated metal],Volcoino/15/4,Volcoino/15);
				noAdventure = true;
			}
			else if ( it == $item[fused fuse] )
				fusedFuse = true;
			if ( (cheapestItem == $item[none] || VolcanoQuestCost(it) < VolcanoQuestCost(cheapestItem)) && retrieve_item(qty,it) )
				cheapestItem = it;
		}

		if ( cheapestItem == $item[none] && fusedFuse && usesRemaining($item[Clara's bell]) && !bossKilling
			&& (!Drunk() || available_amount($item[drunkula's wineglass])>0 )
			&& user_confirm("Do you want to use Clara's Bell to pick up a fused fuse for the volcano quest?",60000,get_property_bool("Dic.UseClara")) )
		{
			if ( !Drunk() || equip($item[drunkula's wineglass]) ) {
				use(1,$item[Clara's Bell]);
				cli_execute("mood apathetic");
				set_property("choiceAdventure1091",7);
				adv1($location[LavaCo&trade; Lamp Factory], -1, "");
			}
			if ( retrieve_item(1,$item[fused fuse]) )
				cheapestItem = $item[fused fuse];
			else
				print("Failed to get the fused fuse, instead encountered: "+get_property("lastEncounter"));
		}


		if ( cheapestItem == $item[none] && noAdventure )
			print("Couldn't acquire volcano quest items cheaply","red");
		else if ( cheapestItem != $item[none] ) {
			visitVolcanoBunker();
			for i from 1 to 3 {
				if ( cheapestItem == to_item(get_property("_volcanoItem"+i)) ) {
					run_choice(i);
					break;
				}
			}
		}
		else
			print("No zero-adventure volcano quests today","orange");
	}
}

void Volcano() {
	if ( !(get_property_bool("_hotAirportToday") || get_property_bool("hotAirportAlways")) || !is_unrestricted($item[Airplane Charter: that 70s Volcano]) )
		return;

	getTowerCoin();
	VolcanoQuest();
}

/*******************************************************\
*					Dinseylandfill
\*******************************************************/
static {
	string questLog = "questlog.php?which=1";
	string dinseyKiosk = "place.php?whichplace=airport_stench&action=airport3_kiosk";

	record dinseyQuestData {
		int priority;
		string questNameKiosk;
		string questNameQuestLog;
		string questStateProperty;
		string questProgressProperty;
		int questProgressLimit;
		boolean canUseWanderers;
		item requiredItem;
		location questLocation;
	};

	dinseyQuestData [string] dinseyQuest;
	dinseyQuest["lube"] 	= new dinseyQuestData(0,"Track Maintenance",			"Super Luber",					"questEStSuperLuber",		"",								0,	false,	$item[lube-shoes],			$location[Barf Mountain]);
	dinseyQuest["food"] 	= new dinseyQuestData(1,"Guest Sustenance Assurance",	"Will Work With Food",			"questEStWorkWithFood",		"dinseyTouristsFed",			30,	false,	$item[none],				$location[Barf Mountain]);
	dinseyQuest["fuel"] 	= new dinseyQuestData(2,"Electrical Maintenance",		"Give Me Fuel",					"questEStGiveMeFuel",		"",								0,	false,	$item[none],				$location[The Toxic Teacups]);
	dinseyQuest["sexism"] 	= new dinseyQuestData(3,"Sexism Reduction",				"Social Justice Adventurer I",	"questEStSocialJusticeI",	"dinseySocialJusticeIProgress",	15,	true,	$item[none],				$location[Pirates of the Garbage Barges]);
	dinseyQuest["racism"] 	= new dinseyQuestData(4,"Racism Reduction",				"Social Justice Adventurer II",	"questEStSocialJusticeII",	"dinseySocialJusticeIIProgress",15,	true,	$item[none],				$location[Uncle Gator's Country Fun-Time Liquid Waste Sluice]);
	dinseyQuest["fun"] 		= new dinseyQuestData(5,"Compulsory Fun",				"Whistling Zippity-Doo-Dah",	"questEStZippityDooDah",	"dinseyFunProgress",			15,	true,	$item[Dinsey mascot mask],	$location[The Toxic Teacups]);
	dinseyQuest["trash"] 	= new dinseyQuestData(6,"Waterway Debris Removal",		"Teach a Man to Fish Trash",	"questEStFishTrash",		"dinseyFilthLevel",				0,	true,	$item[trash net],			$location[Pirates of the Garbage Barges]);
	dinseyQuest["bear"] 	= new dinseyQuestData(7,"Bear Removal",					"Nasty\, Nasty Bears",			"questEStNastyBears",		"dinseyNastyBearsDefeated",		8,	false,	$item[none],				$location[Uncle Gator's Country Fun-Time Liquid Waste Sluice]);
}

void disposeGarbage() {
	if ( usesRemaining("_dinseyGarbageDisposed") && StockUp(1,$item[bag of park garbage],234,234) ) {
		visit_url("place.php?whichplace=airport_stench&action=airport3_tunnels");
		page = visit_url("choice.php?whichchoice=1067&pwd&option=6");
		if ( usesRemaining("_dinseyGarbageDisposed") ) {
			if ( contains_text(page,"Your park cleanup quota for today has already been met.") )
				set_property("_dinseyGarbageDisposed",true);
			else
				abort("We failed to dispose garbage somehow?");
		}
	}
}

boolean DinseyHasQuest() {
	foreach quest,Q in dinseyQuest
		if ( quest == "" ) {
			print("charters: removing empty quest data","red");
			remove dinseyQuest[""];
			return false;
		}
		else if ( get_property(Q.questStateProperty) != "unstarted" )
			return true;
	return false;
}

string DinseyActiveQuest() {
	foreach quest,Q in dinseyQuest
		if ( get_property(Q.questStateProperty) != "unstarted" )
			return quest;
	return "";
}

boolean DinseyQuestComplete() {
	if ( DinseyHasQuest() ) {
		string quest = DinseyActiveQuest();
		switch(quest) {
			case "fuel":
				return StockUp(20,$item[toxic globule],itemValue($item[FunFunds&trade;])*3/20/2,itemValue($item[FunFunds&trade;])*3/20);
			case "lube":
				return contains_text(visit_url(questLog),"<b>Kiosk</b>");
			case "trash":
				return get_property_int(dinseyQuest[quest].questProgressProperty) <= dinseyQuest[quest].questProgressLimit && contains_text(visit_url(questLog),"<b>Kiosk</b>");
			case "fun":
			case "sexism":
			case "racism":
				return get_property_int(dinseyQuest[quest].questProgressProperty) >= dinseyQuest[quest].questProgressLimit && contains_text(visit_url(questLog),"<b>Kiosk</b>");
			default:
				return get_property_int(dinseyQuest[quest].questProgressProperty) >= dinseyQuest[quest].questProgressLimit;
		}
	}
	else
		return false;
}

boolean DinseyHasActiveQuest() {
	return DinseyHasQuest() && !DinseyQuestComplete();
}

void DinseyPickQuest() {
	string [int,int] QuestsOffered;
	string [int] quests;
	int best;
	string bestquest;
	boolean doBarf = get_property_bool("_Dic.Barfday");		// Might as well take barf quests if we're barffarming

	if ( DinseyHasQuest() )
		return;

	if ( get_property_bool("_Charters.DinseyQuestStartedToday") || get_property_bool("_Charters.DinseyQuestsAvoided") )
		return;

	string page = visit_url(dinseyKiosk);
	QuestsOffered = group_string(page,"width=250><center><b>([^<]+)</b></center>");

	foreach i,j in QuestsOffered
		if ( j == 1 )
			print("Quest "+(i+1)+": "+QuestsOffered[i,j]);

	if ( count(QuestsOffered) == 1 ) {
		if ( QuestsOffered[0,1] == dinseyQuest[DinseyActiveQuest()].questNameKiosk )
			print("Already on dinsey quest "+dinseyQuest[DinseyActiveQuest()].questNameKiosk,"orange");
		else
			abort("Trouble parsing offered dinsey quests, the only one we found doesn't match our active quest");
	}
	else if ( count(QuestsOffered) == 2) {
		for i from 1 to 2 {
			foreach quest,Q in dinseyQuest {
				if ( Q.questNameKiosk == QuestsOffered[i-1,1] ) {
					quests[i] = quest;
					if ( ( quest == "fuel" && StockUp(20,$item[toxic globule],itemValue($item[FunFunds&trade;])*3/20/2,itemValue($item[FunFunds&trade;])*3/20)
						|| Q.canUseWanderers
						|| Q.questLocation == $location[Barf Mountain] && doBarf)
							&& ( best == 0 || Q.priority < dinseyQuest[bestquest].priority ) )
					{
						best = i;
						bestquest = quest;
					}
					break;
				}
			}
		}

		if ( best != 0 ) {
			print("Selecting dinsey quest: "+dinseyQuest[quests[best]].questNameKiosk,"blue");
			page = visit_url(dinseyKiosk);
			if ( available_choice_options() contains best ) {
				run_choice(best);
				set_property("_Charters.DinseyQuestStartedToday",true);
			}
			else
				abort("pickDinseyQuest can't find the right choice somehow?");
		}
		else {
			set_property("_Charters.DinseyQuestsAvoided",true);
			print("No dinsey quests that you want today","blue");
		}
	}
	else if ( contains_text(page,"You already took a job assignment for today.") ) {
		set_property("_Charters.DinseyQuestStartedToday",true);
		run_choice(6);
	}
	else
		print("Trouble parsing offered dinsey quests, found "+count(QuestsOffered)+" offers.","red");
}

void DinseyTurnInQuest() {
	if ( DinseyQuestComplete() ) {
		if ( DinseyActiveQuest() == "racism" )
			set_property("questEStSocialJusticeI","unstarted");
		visit_url(dinseyKiosk);
		run_choice(3);
	}
}

void Dinsey() {
	if ( !get_property_bool("_stenchAirportToday") && !get_property_bool("stenchAirportAlways") )
		return;

	disposeGarbage();
	DinseyTurnInQuest();
	DinseyPickQuest();
	DinseyTurnInQuest();
}

/*******************************************************\
*					Glaciest
\*******************************************************/
static {
	string walford = "place.php?whichplace=airport_cold&action=glac_walrus";

	record glaciestQuestData {
		int priority;
		boolean [location] combatLocations;
		boolean [location] noncombatLocations;
		item requiredItem;
		string maximize;
	};

	boolean [location] Hotel = $locations[The Ice Hotel];
	boolean [location] VYKEA = $locations[VYKEA];
	boolean [location] both = $locations[The Ice Hotel,VYKEA];

	glaciestQuestData [string] glaciestQuest;
	glaciestQuest["balls"] 		= new glaciestQuestData(1,VYKEA,VYKEA,$item[none],", item, 50 max");			// covered by passives
	glaciestQuest["chum"] 		= new glaciestQuestData(2,VYKEA,both ,$item[Mr. Screege's spectacles],", 2 meat drop, 100 max");	// nearly covered by passives
	glaciestQuest["blood"] 		= new glaciestQuestData(3,both ,Hotel,$item[none],"");							// bleed damage in combat (covered by tin snips in combat macro)
	glaciestQuest["bolts"] 		= new glaciestQuestData(4,VYKEA,both ,$item[VYKEA hex key],"");
	glaciestQuest["chicken"] 	= new glaciestQuestData(5,Hotel,Hotel,$item[sardine can key],", 5 food drop, 50 max");
	glaciestQuest["milk"] 		= new glaciestQuestData(6,Hotel,VYKEA,$item[norwhal helmet],", 5 booze drop, 50 max");
	glaciestQuest["moonbeams"] 	= new glaciestQuestData(7,both ,both ,$item[none],""); 							// no hat
	glaciestQuest["ice"] 		= new glaciestQuestData(8,both ,Hotel,$item[none],"");							// 10 cold damage in combat (cold immune monsters only)
	glaciestQuest["rain"] 		= new glaciestQuestData(9,Hotel,VYKEA,$item[none],"");							// 100 hot damage in combat
}

boolean GlaciestHasQuest() {
	return ( get_property("questECoBucket") != "unstarted" && get_property("walfordBucketItem") != "" );
}

string GlaciestActiveQuest() {
	return get_property("walfordBucketItem");
}

void GlaciestPickQuest() {
	string [int,int] QuestsOffered;
	int best,bestValue;
	if ( GlaciestHasQuest() )
		return;

	if ( !is_unrestricted($item[Airplane Charter: The Glaciest]) || get_property_bool("_walfordQuestStartedToday") )
		return;

	string page = visit_url(walford);
	QuestsOffered = group_string(page,"\\b(balls|blood|bolts|chicken|chum|ice|milk|moonbeams|rain)\\b(?=\")");

	if ( count(QuestsOffered) == 3 ) {
		foreach i in QuestsOffered {
			print("Quest "+(i+1)+": "+QuestsOffered[i,1]);
			if ( bestValue == 0 || glaciestQuest[QuestsOffered[i,1]].priority < bestValue ) {
				best = i+2;
				bestValue = glaciestQuest[QuestsOffered[i,1]].priority;
			}
		}

		if ( best != 0 ) {
			print("Selecting Glaciest quest: "+QuestsOffered[best-2,1],"blue");
			if ( available_choice_options() contains best )
				run_choice(best);
			else
				abort("pickGlaciestQuest can't find the right choice somehow?");
		}
	}
	else
		abort("Trouble parsing offered Glaciest quests, found "+count(QuestsOffered)+" offers.");
}

boolean GlaciestQuestComplete() {
	return (get_property_int("walfordBucketProgress") >= 100);
}

boolean GlaciestHasActiveQuest() {
	return GlaciestHasQuest() && !GlaciestQuestComplete();
}

void GlaciestTurnInQuest() {
	if ( GlaciestQuestComplete() ) {
		if ( equipped_item($slot[off-hand]) == $item[walford's bucket] )
			equip($slot[off-hand],$item[none]);
		visit_url(walford);
		run_choice(1);
	}
}

void Glaciest() {
	if ( !get_property_bool("_coldAirportToday") && !get_property_bool("coldAirportAlways") )
		return;

	GlaciestTurnInQuest();
	GlaciestPickQuest();
	GlaciestTurnInQuest();
}

/*******************************************************\
*					Spring Break Beach
\*******************************************************/

boolean UMDAvailable() {
	return dateDiff("yyyy-MM-dd",get_property("umdLastObtained"),"yyyyMMdd",today_to_string()) >= 7;
}

void collectUMD() {


	if ( UMDAvailable() && usesRemaining($item[Clara's bell]) && !bossKilling
		&& ( boolean_modifier("Adventure Underwater") || equip($item[mer-kin scholar mask]) || equip($item[mer-kin gladiator mask]) || equip($item[aerated diving helmet]) || equip($item[old SCUBA tank]) )
		&& ( boolean_modifier("Underwater Familiar") || use_familiar($familiar[none]) )
		&& ( !Drunk() || equip($item[drunkula's wineglass]) )
		&& !has_effect($effect[smart drunk])
		&& user_confirm("Do you want to use Clara's Bell to pick up an Ultimate Mind Destroyer in Spring Break Beach?",60000,get_property_bool("Dic.UseClara")) )
	{
		use(1,$item[Clara's Bell]);
		cli_execute("mood apathetic");
		set_property("choiceAdventure918",1);
		fullHeal();
		repeat {
			adv1($location[The Sunken Party Yacht], -1, "");
		}
		until ( !($Strings[a pound of cure, wooof! wooooooof!, your dog found something again, welcome to you!, yacht\, see?] contains stripLastEncounter() ) );
		if ( stripLastEncounter() != "yachtzee!" )
			print("Failed to get the Ultimate Mind Destroyer, instead encountered: "+get_property("lastEncounter"));
	}

}

void SpringBreakBeach() {
	if ( !is_unrestricted($item[Airplane Charter: Spring Break Beach]) || !get_property_bool("_sleazeAirportToday") && !get_property_bool("sleazeAirportAlways") )
		return;

	collectUMD();
}

/*******************************************************\
*					Conspiracy Island
\*******************************************************/

static {
	string radio = "place.php?whichplace=airport_spooky&action=airport2_radio";
	string omegapanel = "place.php?whichplace=airport_spooky_bunker&action=si_controlpanel";

	record conspiracyQuestData {
		int reward;
		string questStateProperty;
		int questProgressLimit;
		string questProgressProperty;
		boolean canUseWanderers;
		boolean canUseRunaways;
		boolean cleeshSafe;
		location questLocation;
		item requiredItem;
		string maximize;
	};

	conspiracyQuestData [string] conspiracyQuest;
	conspiracyQuest["Serum"]	= new conspiracyQuestData(30,	"questESpSerum",		5,	"",						false,	false,	false,	$location[The Mansion of Dr. Weirdeaux],		$item[none],"10 item, 10 pickpocket chance");
	conspiracyQuest["Clipper"]	= new conspiracyQuestData(20,	"questESpClipper",		23,	"fingernailsClipped",	false,	true,	false,	$location[The Mansion of Dr. Weirdeaux],		$item[none],"");
	conspiracyQuest["EVE"]		= new conspiracyQuestData(30,	"questESpEVE",			0,	"",						true,	true,	true,	$location[The Secret Government Laboratory],	$item[none],"");
	conspiracyQuest["Medium"]	= new conspiracyQuestData(30,	"questESpFakeMedium",	0,	"",						true,	true,	true,	$location[The Secret Government Laboratory],	$item[none],"");
	conspiracyQuest["Gore"]		= new conspiracyQuestData(20,	"questESpGore",			100,"goreCollected",		true,	false,	false,	$location[The Secret Government Laboratory],	$item[gore bucket],"10 meat");
	conspiracyQuest["Pun"]		= new conspiracyQuestData(20,	"questESpJunglePun",	11,	"junglePuns",			true,	false,	false,	$location[The Deep Dark Jungle],				$item[encrypted micro-cassette recorder],"mys");
	conspiracyQuest["Order"]	= new conspiracyQuestData(30,	"questESpOutOfOrder",	99,	"",						true,	false,	false,	$location[The Deep Dark Jungle],				$item[GPS-tracking wristwatch],"10 Initiative");
	conspiracyQuest["Smokes"]	= new conspiracyQuestData(30,	"questESpSmokes",		10,	"",						false,	false,	false,	$location[The Deep Dark Jungle],				$item[none],"10 item, 10 pickpocket chance");

	record setting {
		item drop;
		boolean [monster] m;
	};
	setting [int] Panel;
	Panel[1] = new setting($item[none],$monsters[government scientist]);
	Panel[2] = new setting($item[battery-powered drill],$monsters[government scientist]);
	Panel[3] = new setting($item[none],$monsters[lab monkey]);
	Panel[4] = new setting($item[monkey barf],$monsters[lab monkey]);
	Panel[5] = new setting($item[none],$monsters[creepy little girl]);
	Panel[6] = new setting($item[cuddly teddy bear],$monsters[creepy little girl]);
	Panel[7] = new setting($item[none],$monsters[super-sized Cola Wars soldier]);
	Panel[8] = new setting($item[khaki duffel bag],$monsters[super-sized Cola Wars soldier]);
	Panel[9] = new setting($item[airborne mutagen],$monsters[government scientist,lab monkey,creepy little girl,super-sized Cola Wars soldier]);
}

boolean ConspiracyHasQuest() {
	foreach quest,Q in conspiracyQuest
		if ( quest == "" ) {
			print("Charters: removing empty quest data","red");
			remove conspiracyQuest[""];
			return false;
		}
		else
		if ( get_property(Q.questStateProperty) != "unstarted" && get_property(Q.questStateProperty) != "finished" )
			return true;
	return false;
}

string ConspiracyActiveQuest() {
	foreach quest,Q in conspiracyQuest
		if ( get_property(Q.questStateProperty) != "unstarted" && get_property(Q.questStateProperty) != "finished" )
			return quest;
	return "";
}

boolean ConspiracyQuestComplete() {
	if ( !ConspiracyHasQuest() )
		return false;
	return get_property(conspiracyQuest[ConspiracyActiveQuest()].questStateProperty) == ( conspiracyQuest[ConspiracyActiveQuest()].requiredItem == $item[none] ? "step1" : "step2" );
}

boolean ConspiracyHasActiveQuest() {
	return ConspiracyHasQuest() && !ConspiracyQuestComplete();
}

void ConspiracyPickQuest() {
	if ( ConspiracyHasQuest() || get_property_bool("_Charters.ConspiracyQuestStartedToday") || get_property_bool("_Charters.ConspiracyQuestsAvoided") )
		return;


	if ( get_property("_questESp") == "" ) {
		if ( handling_choice() && last_choice() != 984 ) {
			page = visit_url("main.php");
		}
		page = visit_url(radio);
		int breakout;
		while ( get_property("_questESp") == "" && handling_choice() && last_choice() == 984 && breakout <= 37 ) {
			run_choice(5);
			breakout++;
		}
		if ( get_property("_questESp") == "" )
			abort("Charters: couldn't parse conspiracy quest, breakout limit reached.");
	}

	foreach quest,Q in conspiracyQuest
		if ( get_property("_questESp") == Q.questStateProperty ) {
			print("Conspiracy quest of the day: "+quest,"blue");
			if ( Q.canUseWanderers || quest == "Clipper" || quest=="Smokes" || quest=="Serum" && StockUp(5,$item[experimental serum P-00],ItemValue($item[Coinspiracy])/24,ItemValue($item[Coinspiracy])/6) ) {
				visit_url(radio);
				set_property("_Charters.ConspiracyQuestStartedToday",true);
				run_choice(1);
			}
			else {
				set_property("_Charters.ConspiracyQuestsAvoided",true);
				print("No conspiracy quests that you want today","blue");
				break;
			}
		}
}

void ConspiracyCompleteQuest() {
	if ( !ConspiracyHasActiveQuest() )
		return;

	boolean claraUsed = false;
	switch (ConspiracyActiveQuest()) {
		case "Serum":
			StockUp(5,$item[experimental serum P-00],ItemValue($item[Coinspiracy])/24,ItemValue($item[Coinspiracy])/6);
			break;
		case "EVE":
		case "Medium":
			if ( $location[The Secret Government Laboratory].turns_spent - get_property_int("Dic.SecretLabNoncombatTimer") < 0 )
				set_property("Dic.SecretLabNoncombatTimer",$location[The Secret Government Laboratory].turns_spent);
			if ( $location[The Secret Government Laboratory].turns_spent - get_property_int("Dic.SecretLabNoncombatTimer") < 15
					&& usesRemaining($item[Clara's bell]) && get_property_bool("Dic.UseClara") && NEPDone() && !UMDAvailable()
					&& use(1,$item[Clara's bell]) )
				claraUsed = true;
			if ( ($location[The Secret Government Laboratory].turns_spent - get_property_int("Dic.SecretLabNoncombatTimer") > 20 || claraUsed)
				&& !has_effect($effect[Steely-Eyed Squint])
				&& !bossKilling )
			{
				try {
					cli_execute("mood apathetic");
					string aas = get_property("afterAdventureScript");
					set_property("afterAdventureScript","");
					equip($slot[acc1],$item[Personal Ventilation Unit]);
					fullHeal();
					if ( ConspiracyActiveQuest() == "EVE" )
						maximize("mainstat, equip Personal Ventilation Unit",false);
					adv1($location[The Secret Government Laboratory],-1,"");
				} finally {
					set_property("afterAdventureScript",aas);
				}
			}
			// Also handled with runaways in Electrofishing.ash
			break;

		case "Gore":
		case "Pun":
		case "Order":
			// Handled with wandering monsters in afterAdventure.ash
			break;
		case "Clipper":
			// Handled with runaways in Electrofishing.ash
			break;
		case "Smokes":
			// Handled by free kills in SandwormSummon.ash
			break;
	}
}

void ConspiracyTurnInQuest() {
	if ( ConspiracyQuestComplete() ) {
		visit_url(radio);
		run_choice(1);
	}
}

void ConspiracyOmegaDevice() {
	if ( usesRemaining("_controlPanelUsed") ) {
		visit_url(omegapanel);
		int best = 1;
		int bestValue = 0;
		foreach i,s in Panel
			if ( !get_property_bool("controlPanel"+i) && itemValue(s.drop) >= bestValue ) {
				best = i;
				bestValue = itemValue(s.drop);
			}
		run_choice(best);
	}

	if ( get_property_int("controlPanelOmega") >= 100 ) {
		visit_url(omegapanel);
		run_choice(10);
	}
}

void ConspiracyIsland() {
	if ( !get_property_bool("_spookyAirportToday") && !get_property_bool("spookyAirportAlways") )
		return;

	ConspiracyTurnInQuest();
	ConspiracyOmegaDevice();
	ConspiracyPickQuest();
	ConspiracyCompleteQuest();
	ConspiracyTurnInQuest();
}