@echo off
setlocal

:::::::::::::::::::::::::::::::::::::::::::::::::
:: CONFIG

set DEV_ROOT=G:\Projects\djnd\parlameter
set DB_ROOT=%DEV_ROOT%\parladb

set MONGO_USERNAME=
set MONGO_PASSWORD=

:::::::::::::::::::::::::::::::::::::::::::::::::
:: PRECONDITIONS / DB

echo Changing directory to: %DEV_ROOT%
cd /d %DEV_ROOT%
echo.

:: check db path
if not exist "%DB_ROOT%\*" (
    echo Creating db directory
    mkdir %DB_ROOT%
)

:: check if mongod is in path
where /q mongod
IF ERRORLEVEL 1 (
    echo.
    echo Can't find "mongod" in PATH. Make sure it's installed and available.
    goto :EOF
)

:: start db
echo Starting mongod...
start /b mongod --dbpath %DB_ROOT% --logpath %DB_ROOT%\parladb.log -new_console:bn
:: --- tab #2

:::::::::::::::::::::::::::::::::::::::::::::::::
:: TABS

echo Starting parlanode...
cmd /k "%CMDER_ROOT%\vendor\init.bat & cd /d %DEV_ROOT%\parlanode & yarn run dev" -new_console:n:t:"parlanode"
:: --- tab #3

echo Starting parlasite...
cmd /k "%CMDER_ROOT%\vendor\init.bat & cd /d %DEV_ROOT%\parlasite & yarn run dev" -new_console:sV:n:t:"parlasite"
:: --- tab #4

echo Starting parlassets...
cmd /k "%CMDER_ROOT%\vendor\init.bat & cd /d %DEV_ROOT%\parlassets & yarn run dev" -new_console:s3TH:n:t:"ass watch"
:: --- tab #5

echo Starting parlassets server...
cmd /k "%CMDER_ROOT%\vendor\init.bat & cd /d %DEV_ROOT%\parlassets & yarn run serve" -new_console:s4TH:n:t:"ass serve"
:: --- tab #6

goto :EOF