//This script fixes the broken recipes for MrCrayFish's Furniture Mod that duplicate items

//First we need to make an ore list of all the axes in the game
val axes = <ore:listAllAxe>;
axes.add(<minecraft:iron_axe:*>);
axes.add(<minecraft:wooden_axe:*>);
axes.add(<minecraft:stone_axe:*>);
axes.add(<minecraft:diamond_axe:*>);
axes.add(<minecraft:golden_axe:*>);
axes.add(<botania:manasteelaxe:*>);
axes.add(<botania:elementiumaxe:*>);
axes.add(<iceandfire:silver_axe:*>);
axes.add(<iceandfire:dragonbone_axe:*>);
axes.add(<iceandfire:myrmex_desert_axe:*>);
axes.add(<iceandfire:myrmex_jungle_axe:*>);
axes.add(<immersiveengineering:axe_steel:*>);
axes.add(<thaumcraft:thaumium_axe:*>);
axes.add(<thaumcraft:void_axe:*>);
axes.add(<thaumcraft:elemental_axe:*>);
axes.add(<twilightforest:ironwood_axe:*>);
axes.add(<twilightforest:steeleaf_axe:*>);
axes.add(<twilightforest:minotaur_axe_gold:*>);
axes.add(<twilightforest:minotaur_axe:*>);
axes.add(<twilightforest:knightmetal_axe:*>);

recipes.removeShapeless(<cfm:item_log>);
recipes.removeShaped(<cfm:item_log>);
recipes.addShapeless(<cfm:item_log> * 8, [<ore:listAllAxe>.transformDamage(), <ore:logWood>]);

recipes.remove(<cfm:item_ink_cartridge>);
recipes.addShaped(<cfm:item_ink_cartridge>, [[<ore:stone>,<ore:stone>,<ore:stone>],
											 [<ore:stone>,<ore:dyeBlack>,<ore:stone>],
											 [<ore:stone>,<ore:stone>,<ore:stone>]]);


recipes.remove(<cfm:item_soap_water>);
recipes.addShapeless(<cfm:item_soap_water>, [<minecraft:water_bucket>.noReturn(),<cfm:item_soap>]);
recipes.remove(<cfm:item_super_soap_water>);
recipes.addShaped(<cfm:item_super_soap_water>, [[<ore:ingotGold>,<ore:ingotGold>,<ore:ingotGold>],
												[<ore:ingotGold>,<cfm:item_soap_water>.noReturn(),<ore:ingotGold>],
												[<ore:ingotGold>,<ore:ingotGold>,<ore:ingotGold>]]);