{$CLEO}
{$INCLUDE SF}
0000:

repeat
wait 0
until Samp.Available()
0B34: samp register_client_command "fakeincar" to_label @cmd
0BE2: raknet setup_outcoming_packet_hook @hook

while true
repeat
wait 0
until 30@ == 1
0AFF: samp 2@ = car_handle_by_samp_vehicle_id 1@
if 056E: car 2@ defined
then
if 31@ == 1
then
wait 400
31@ = 0
end // если мы только что включили эту хрень, ждём 400 мс перед отправкой инкар даты
00AA: store_car 2@ position_to 5@ 6@ 7@
0227: 8@ = car 2@ health
0093: 9@ = integer 8@ to_float // переводим инт в флоат для адекватной записи в флоат
0A96: 10@ = actor $PLAYER_ACTOR struct // получаем структуру
0A8E: 11@ = 10@ + 0x540 // // получаем адрес памяти с хп
0A8D: 12@ = read_memory 11@ size 4 virtual_protect 1 // читаем
0092: 13@ = float 12@ to_integer // мы получили флоат, переводим в инт чтобы в дальнейшем адекватно записать в битстрим байт
0A8E: 14@ = 10@ + 0x548 // // получаем адрес памяти с броней
0A8D: 15@ = read_memory 14@ size 4 virtual_protect 1 // читаем
0092: 16@ = float 15@ to_integer // мы получили флоат, переводим в инт чтобы в дальнейшем адекватно записать в битстрим байт

0B3D: raknet 4@ = new_bit_stream
0BEA: raknet bit_stream 4@ reset_write_pointer
0B40: raknet bit_stream 4@ write PACKET_VEHICLE_SYNC type BS_TYPE_BYTE size 1 // packetid
0B40: raknet bit_stream 4@ write 1@ type BS_TYPE_SHORT size 2 // ид кара
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_SHORT size 2 // кнопки, если не записать сюда ноль там будет мусор и в итоге мы получим кик
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_SHORT size 2 // кнопки, если не записать сюда ноль там будет мусор и в итоге мы получим кик
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_SHORT size 2 // кнопки, если не записать сюда ноль там будет мусор и в итоге мы получим кик
0B40: raknet bit_stream 4@ write 0.700332 type BS_TYPE_FLOAT size 4 // fQuaternion[0]
0B40: raknet bit_stream 4@ write 0.003405 type BS_TYPE_FLOAT size 4 // fQuaternion[1]
0B40: raknet bit_stream 4@ write -0.003468 type BS_TYPE_FLOAT size 4 // fQuaternion[2]
0B40: raknet bit_stream 4@ write 0.713800 type BS_TYPE_FLOAT size 4 // fQuaternion[3]
0B40: raknet bit_stream 4@ write 5@ type BS_TYPE_FLOAT size 4 // vehPos[0]
0B40: raknet bit_stream 4@ write 6@ type BS_TYPE_FLOAT size 4 // vehPos[1]
0B40: raknet bit_stream 4@ write 7@ type BS_TYPE_FLOAT size 4 // vehPos[2]
0B40: raknet bit_stream 4@ write 0.0 type BS_TYPE_FLOAT size 4 // скорость, если не записать сюда ноль там будет мусор и в итоге мы получим кик
0B40: raknet bit_stream 4@ write 0.0 type BS_TYPE_FLOAT size 4 // скорость, если не записать сюда ноль там будет мусор и в итоге мы получим кик
0B40: raknet bit_stream 4@ write 0.0 type BS_TYPE_FLOAT size 4 // скорость, если не записать сюда ноль там будет мусор и в итоге мы получим кик
0B40: raknet bit_stream 4@ write 9@ type BS_TYPE_FLOAT size 4 // vehHealth
0B40: raknet bit_stream 4@ write 13@ type BS_TYPE_BYTE size 1 // playerHP
0B40: raknet bit_stream 4@ write 16@ type BS_TYPE_BYTE size 1 // playerArmour
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_BYTE size 1 // Всякая хуйня, опять же, чтобы не было мусора
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_BYTE size 1 // Всякая хуйня, опять же, чтобы не было мусора
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_BYTE size 1 // Всякая хуйня, опять же, чтобы не было мусора
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_SHORT size 2 // Всякая хуйня, опять же, чтобы не было мусора
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_SHORT size 2 // Всякая хуйня, опять же, чтобы не было мусора
0B40: raknet bit_stream 4@ write 0 type BS_TYPE_SHORT size 2 // Всякая хуйня, опять же, чтобы не было мусора
0B40: raknet bit_stream 4@ write 0.0 type BS_TYPE_FLOAT size 4 // Всякая хуйня, опять же, чтобы не было мусора
0B8B: raknet send bit_stream 4@
0B3E: raknet delete_bit_stream 4@
wait 70 // перед отправкой следующего пакета немного подождем чтобы не делать это слишком часто
else
30@ = 0
chatmsg "Кар пропал" -1
end
end

:cmd
0B35: samp 0@ = get_last_command_params
0AD4: 0@ = scan_string 0@ format "%d" 1@
0AFF: samp 2@ = car_handle_by_samp_vehicle_id 1@
if 056E: car 2@ defined
then
30@ = 1
31@ = 1
0B30: samp send_enter_vehicle 1@ as_passenger 0
chatmsg "ок, начинаем" -1
end
Samp.CmdRet()

:hook
if 30@ == 1 // если с каром всё окей, блочим исходящую онфут дату
then
0BE5: raknet 3@ = get_hook_param PARAM_PACKETID
if 3@ == PACKET_PLAYER_SYNC
then
0BE0: raknet hook_ret false
end
end
0BE0: raknet hook_ret true