NodeMCU hotspot 2-pin switch v1.0

/*
   nodemcu_experiment_004
   NodeMCU stand-alone wifi hot spot - v2.0
   November 24, 2019

   This sketch is a combination of two others:
   https://randomnerdtutorials.com/esp8266-web-server/ (a wifi/web page that controls 2 I/O pins)
   https://tttapa.github.io/ESP8266/Chap07%20-%20Wi-Fi%20Connections.html (see "Access Point Mode")

   This works much faster than v1.0.
*/

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>

const char *ssid = "esp8266stn"; // ------ (8 chars minimum?)
const char *password = "asdf1234"; // ------- (8 chars minimum?)

WiFiServer server(80);

WiFiClient client;

String header;

String output5State = "off";
String output4State = "off";

const int output5 = 5;
const int output4 = 4;

unsigned long currentTime = millis();
unsigned long previousTime = 0;

String currentLine = "";                // make a String to hold incoming data from the client

const long timeoutTime = 2000;

int wifi_access_point1 = 0;


void setup() {
  Serial.begin(115200);
  Serial.println();
  Serial.print("Configuring access point...");
  /* You can remove the password parameter if you want the AP to be open. */
  WiFi.softAP(ssid, password);
  server.begin();
  Serial.println("HTTP server started");

  pinMode(output5, OUTPUT);
  pinMode(output4, OUTPUT);
  digitalWrite(output5, LOW);
  digitalWrite(output4, LOW);
}

void loop() {

  switch (wifi_access_point1) {
    case 0:
      client = server.available();   // Listen for incoming clients
      if (client) {                             // If a new client connects,
        wifi_access_point1 = 1;
      }
      break;
    case 1:
      Serial.println("New Client.");          // print a message out in the serial port
      //String currentLine = "";                // make a String to hold incoming data from the client
      currentTime = millis();
      previousTime = currentTime;
      wifi_access_point1 = 2;
      break;
    case 2:
      send_webPage();
      break;
    case 3:
      // Clear the header variable
      header = "";
      // Close the connection
      client.stop();
      Serial.println("Client disconnected.");
      Serial.println("");
      wifi_access_point1 = 0;
      break;
  }

} // end of main loop()


void send_webPage() {
  if (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
    currentTime = millis();
    if (client.available()) {             // if there's bytes to read from the client,
      char c = client.read();             // read a byte, then
      Serial.write(c);                    // print it out the serial monitor
      header += c;
      if (c == '\n') {                    // if the byte is a newline character
        // if the current line is blank, you got two newline characters in a row.
        // that's the end of the client HTTP request, so send a response:
        if (currentLine.length() == 0) {
          // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
          // and a content-type so the client knows what's coming, then a blank line:
          client.println("HTTP/1.1 200 OK");
          client.println("Content-type:text/html");
          client.println("Connection: close");
          client.println();

          // turns the GPIOs on and off
          if (header.indexOf("GET /5/on") >= 0) {
            Serial.println("GPIO 5 on");
            output5State = "on";
            digitalWrite(output5, HIGH);
          } else if (header.indexOf("GET /5/off") >= 0) {
            Serial.println("GPIO 5 off");
            output5State = "off";
            digitalWrite(output5, LOW);
          } else if (header.indexOf("GET /4/on") >= 0) {
            Serial.println("GPIO 4 on");
            output4State = "on";
            digitalWrite(output4, HIGH);
          } else if (header.indexOf("GET /4/off") >= 0) {
            Serial.println("GPIO 4 off");
            output4State = "off";
            digitalWrite(output4, LOW);
          }

          // Display the HTML web page
          client.println("<!DOCTYPE html><html>");
          client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
          client.println("<link rel=\"icon\" href=\"data:,\">");
          // CSS to style the on/off buttons
          // Feel free to change the background-color and font-size attributes to fit your preferences
          client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
          client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
          client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
          client.println(".button2 {background-color: #77878A;}</style></head>");

          // Web Page Heading
          client.println("<body><h1>ESP8266 Web Server</h1>");

          // Display current state, and ON/OFF buttons for GPIO 5
          client.println("<p>GPIO 5 - State " + output5State + "</p>");
          // If the output5State is off, it displays the ON button
          if (output5State == "off") {
            client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
          } else {
            client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
          }

          // Display current state, and ON/OFF buttons for GPIO 4
          client.println("<p>GPIO 4 - State " + output4State + "</p>");
          // If the output4State is off, it displays the ON button
          if (output4State == "off") {
            client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
          } else {
            client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
          }
          client.println("</body></html>");

          // The HTTP response ends with another blank line
          client.println();
          // Break out of the while loop
          wifi_access_point1 = 3;
        }
        else { // if you got a newline, then clear currentLine
          currentLine = "";
        }
      }
      else if (c != '\r') {  // if you got anything else but a carriage return character,
        currentLine += c;      // add it to the end of the currentLine
      }
    }
  }
  else {
    wifi_access_point1 = 3;
  }
}





// ~~~~~~~~ the end ~~~~~~~~~~~