Slimetube Slow run

script "Seesee_Slimetube_SLOW.ash";
/**************************************************************************************************
This script farms the slimetube for chamois.  It can gather about 900 chamois in about a 1000 turns.
It also automatically levels up different familiars in order to get the 500 pound trophy.
It also automatically collects Groose Grease each day.
It's really made for my own private use, but it could work for others if they have the same gear.
*******************************************************************************************************/

Int Which_Familiar = 1;

int my_starting_adv_count = my_adventures();

Familiar [int] New_Familiar;

New_Familiar[1] = $familiar[Xiblaxian Holo-Companion];
New_Familiar[2] = $familiar[Reassembled Blackbird];
New_Familiar[3] = $familiar[Reanimated Reanimator];
New_Familiar[4] = $familiar[Gelatinous Cubeling];
New_Familiar[5] = $familiar[Exotic Parrot];
New_Familiar[6] = $familiar[Mosquito];
New_Familiar[7] = $familiar[Leprechaun];
New_Familiar[8] = $familiar[Blood-Faced Volleyball];
New_Familiar[9] = $familiar[Stooper];
New_Familiar[10] = $familiar[God Lobster];
New_Familiar[11] = $familiar[Yule Hound];
New_Familiar[12] = $familiar[Grouper Groupie];
New_Familiar[13] = $familiar[Baby Gravy Fairy];
New_Familiar[14] = $familiar[Untamed Turtle];
New_Familiar[15] = $familiar[Sabre-Toothed Lime];
New_Familiar[16] = $familiar[Barrrnacle];
New_Familiar[17] = $familiar[Angry Goat];
New_Familiar[18] = $familiar[Misshapen Animal Skeleton];
New_Familiar[19] = $familiar[Star Starfish];
New_Familiar[20] = $familiar[Levitating Potato];
New_Familiar[21] = $familiar[Adorable Seal Larva];
New_Familiar[22] = $familiar[Jumpsuited Hound Dog];

float[int] slime_percent;

slime_percent[1] = 5.334167;
slime_percent[2] = 4.001677;
slime_percent[3] = 2.9025;
slime_percent[4] = 2.016667;
slime_percent[5] = 1.325;
slime_percent[6] = .805833;
slime_percent[7] = .4391667;
slime_percent[8] = .200833;
slime_percent[9] = .066667;
slime_percent[10] = 0;
slime_percent[11] = 0;

void Get_hatter ()
	{
		cli_execute
			{
				hatter oil cap
            	    	}
	}


void Get_Friars ()
	{
		cli_execute
			{
				friars familiar
            	    	}
	}

void Get_susie ()	#there is no Fortune Teller in Big Timers clan, so we have to jump over to Old CW's clan to get the buff and come back.
	{
		visit_url("showclan.php?recruiter=1&whichclan="+ 14909 +"&pwd&whichclan=" + 14909 + "&action=joinclan&apply=Apply+to+this+Clan&confirm=on");

		cli_execute
			{
				fortune buff familiar
            	    	}

		visit_url("showclan.php?recruiter=1&whichclan="+ 35794 +"&pwd&whichclan=" + 35794 + "&action=joinclan&apply=Apply+to+this+Clan&confirm=on");
	}

void change_Fam()
/**************************************************************************************************
Overview:
	Automatically switches familiars in order to level up enough familiars to get
	the 500 pound trophy.

When is it called?
	It is only called after the Groose familiar has dropped its daily 5 grease.

Buffs Used:
	Susie buff from the Fortune Teller in "Old CW's Germ Free Clan"
	Hatter familiar +experience buff
	Brother Corsican's buff
	Pulled Blue Taffy (if you want)
*******************************************************************************************************/
{
	if ( familiar_weight( New_Familiar[Which_Familiar] ) < 19  ) 	#Checking current familiar to see if it is less than 20 pounds, if it is then use it.
		{
			use_familiar(New_Familiar[Which_Familiar]);
			Which_Familiar = min(Which_Familiar+1,22);	#using min() so when all familiars are lvl.20, we stay with our final familiar.
		}
	else
		{
			Which_Familiar = min(Which_Familiar+1,22);	#getting ready to use next familiar in list.
			change_Fam();					#if our current familiar is more than 19 pounds, then go get another familiar and check it.
		}

	if (get_property("_madTeaParty")==false)	#We can only get these buffs once a day, so don't bother trying if we already got one of them.
		{					#this code is probably out of place here, but...I'll change it later.
			Get_susie();
			Get_Friars();
			Get_hatter();
			use( min(item_amount($item[pulled blue taffy]),30), $item[pulled blue taffy] ); #Gives 300 turns of +10XP buff, but if you have less it's ok.
		}
}

int Expected_slime_damage()
/******* This routine determines the amount of damage expected from your coating of Slime, and the slime monsters attack *********/
{
	int damage = my_maxhp() * slime_percent[ have_effect( $effect[Coated in Slime] ) ];
	return ceil( damage - ( damage * ( elemental_resistance( $element[slime] ) / 100 ) )   ) + expected_damage();
}

Void VerifyUsed_Chamois ()
/******* This routine helps to guard against internet problems and "time out" errors to MAKE SURE you used a Chamois *********/
	{
		while ( have_effect( $effect[Coated in Slime] ) > 0 )
			{
				cli_execute
					{
						/chamois
					}
			}
	}

void VerifyUsed_HealScroll ()
/******* This routine helps to guard against internet problems and "time out" errors to MAKE SURE you used a Heal Scroll *********/
	{
		while (my_hp() < my_maxhp())
			{
				use( 1, $item[scroll of drastic healing] );
			}
	}

void Get_Ready_to_Start()
/***************************************************************************************************************************
	This routine makes some necessary arrangements to get your character ready to begin fighting in the Slimetube.

	 	1. Makes sure you're fighting in the right clan basement!
		2. Makes sure your familiar is the Groose to begin collecting grease.
		3. Puts on the correct outfit.
		4. Double checks your ML by turning off the "radio" and shrugging Ur-kels if active.
		5. Makes sure you have enough Healing scrolls on hand.
		6. Makes sure your Health is at maximum before starting
		7. Makes sure you have enough Healing scrolls on hand.
		8. Checks if you want to continue with less than 30 Pulled Blue Taffy.
*****************************************************************************************************************************/
	{
		if (get_clan_name() != "Big Timers" )
			{
				abort("Hey silly...you're in the wrong clan!");
			}

		cli_execute
			{
				outfit low level slime farming
				mcd 0
				shrug Ur-kel's
				familiar Groose
				ccs default
		        }

		if ( my_hp() < my_maxhp() )
			{
				VerifyUsed_HealScroll ();
			}

		if ( item_amount($item[scroll of drastic healing]) < (my_adventures()/8)+20     )
			{
				abort("You're running out of Heal scrolls.");
			}

		if ( item_amount($item[pulled blue taffy]) < 30 )      #check on the Taffy situation and whether you're happy with it.
			{
				if (user_confirm( "You don't have 30 Pulled Blue Taffy.  Do you want to STOP?" ) )
					{
						abort();
					}
				else
					{
						Print("Ok...continuing with less than 30 Blue Taffy");
					}
			}
	}

void main()
{
	Get_Ready_to_Start();

	while ( my_adventures() > 8 ) 	#...I'm expecting 8 turns before we need to chamois and end the iteration
	{

		if (my_familiar() == $familiar[Bloovian Groose] &&     	# just in case Mafia looses track of "_grooseDrops"!
		    my_adventures() < my_starting_adv_count-29 )	# if we adventured for 30 turns and didn't get 5 "_grooseDrops", something is wrong!
			{
				change_fam();
			}

		if (familiar_weight(my_familiar()) >= 20 &&
		    get_property("_grooseDrops" ).to_int() > 4 ) 	#when we finally get 5 "_grooseDrops" AND our Groose is already lvl.20, then change familiars
			{
				change_fam();
			}

		print( ((my_adventures()/8)+1) + " iterations left.", "blue");	#notification of how many more "for loops" we have remaining
		while (Expected_slime_damage() < my_hp())
			{
				adventure(1, $location[The Slime Tube]);
			}

		VerifyUsed_HealScroll ();

		while (Expected_slime_damage() < my_hp())		#squeezing out a few more advs. before using a Chamois...using heal scrolls instead
			{
				adventure(1, $location[The Slime Tube]);
				VerifyUsed_HealScroll ();
			}

		VerifyUsed_Chamois ();

	}
Print("All done.");
}