-	script	heal_buff	-1,{
if( BaseLevel >= .baselevel ){
	mes "You'll have to pay "+.zeny_cost+"z.";
	if( select( "Heal","Cancel" ) == 1 ){
		if( Zeny < .zeny_cost ){
			mes "You dont have enough zeny.";
			close;
		}else{
			Zeny -= .zeny_cost;
		}
	}
}

// repair all items
if( getbrokenid(1) ) repairall;

// identify all item
getinventorylist;
while( .@i < @inventorylist_count ){
	if( !@inventorylist_identify[.@i] ){
		delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;
		getitem @inventorylist_id[.@i],1;
	}
	.@i++;
}

// buff for all player
percentheal 100,100;
for( .@buff = 0; .@buff < .buff_normal_size; .@buff++ )
	sc_start .buff_normal[.@buff],.buff_normal_time,10;

.@guild_id = getcharid(2);
// check player if they are castle owner
if( .@guild_id ){
	.@i = 0;
	while( .@i < .castle_size ){
		if( .@guild_id == .castle_owner[.@i] ){
			for( .@buff = 0; .@buff < .buff_castle_size; .@buff++ )
				sc_start .buff_castle[.@buff],.buff_castle_time,10;
			break;
		}
		.@i++;
	}
}

// check top player
if( query_sql( "SELECT `char_id` FROM `pvpladder` ORDER BY `kills` DESC LIMIT 10",.@char_id ) ){
	.@char_id_size = getarraysize( .@char_id );
	.@getcharid = getcharid(0);
	.@i = 0;
	while( .@i < .@char_id_size ){
		if( .@getcharid == .@char_id[.@i] ){
			for( .@buff = 0; .@buff < .buff_topplayer_size; .@buff++ )
				sc_start .buff_topplayer[.@buff],.buff_topplayer_time,10;
			break;
		}
		.@i++;
	}
}

// check if player is donator group
if( getgroupid() == .donator_group ){
	for( .@buff = 0; .@buff < .buff_donator_size; .@buff++ )
		sc_start .buff_donator[.@buff],.buff_donator_time,10;
}

// check if player's GM level is a GM
if( getgmlevel() >= .gm_level ){
	for( .@buff = 0; .@buff < .buff_gm_size; .@buff++ )
		sc_start .buff_gm[.@buff],.buff_gm_time,10;
}

specialeffect2 EF_PROVIDENCE;
mes "Thank you.";
close;

OnInit:
if( strnpcinfo(2) != "" ) end;
// base level that will be charged with zeny
.baselevel = 400;
.zeny_cost = 200000;
// donator group id
.donator_group = 1;
// minimum GM level
.gm_level = 80;

// buff list for normal
setarray .buff_normal,SC_BLESSING,SC_INCREASEAGI;
.buff_normal_time = 600000;

// buff list for castle owner
setarray .buff_castle,SC_IMPOSITIO,SC_SUFFRAGIUM,SC_ANGELUS;
.buff_castle_time = 600000;

// buff list for top 10 player
setarray .buff_topplayer,SC_KYRIE,SC_MAGNIFICAT,SC_GLORIA,SC_ENDURE;
.buff_topplayer_time = 600000;

// buff list for donator
setarray .buff_donator,SC_CONCENTRATE,SC_LOUD,SC_ASPDPOTION3,SC_SPEEDUP0;
.buff_donator_time = 600000;

// buff list for GM
setarray .buff_gm,SC_CP_WEAPON,SC_CP_SHIELD,SC_CP_ARMOR,SC_CP_HELM;
.buff_gm_time = 9999999;

// castle map list
setarray .castle$,
	"prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05",
	"gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05",
	"payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05",
	"aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05";

.castle_size = getarraysize( .castle$ );
.buff_normal_size = getarraysize( .buff_normal );
.buff_castle_size = getarraysize( .buff_castle );
.buff_topplayer_size = getarraysize( .buff_topplayer );
.buff_donator_size = getarraysize( .buff_donator );
.buff_gm_size = getarraysize( .buff_gm );

// update everytime WOE End.
OnAgitEnd:
deletearray .castle_owner;
for( .@i = 0; .@i < .castle_size; .@i++ )
	.castle_owner[.@i] = getcastledata( .castle$[.@i],1 );
end;
}


prontera,151,181,5	duplicate(heal_buff)	Heal Buff#1	757
prontera,153,181,5	duplicate(heal_buff)	Heal Buff#2	757
prontera,155,181,5	duplicate(heal_buff)	Heal Buff#3	757
prontera,157,181,5	duplicate(heal_buff)	Heal Buff#4	757
prontera,159,181,5	duplicate(heal_buff)	Heal Buff#5	757