HardStuff build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'

version = "0.2.18"
group= "com.draco18s.harderores" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "1.7.10-HardStuff"

def libVersion = "1.3.0"
def oresVersion = "0.3.0"
def hazardsVersion = "0.2.0"
def wildlifeVersion = "0.2.0"
def prePend = "1.7.10-"

minecraft {
    version = "1.7.10-10.13.2.1291"
    runDir = "eclipse"
    assetDir = "eclipse/assets"
}

dependencies {
    // you may put jars on which you depend on in ./libs
    // or you may define them like so..
    //compile "some.group:artifact:version:classifier"
    //compile "some.group:artifact:version"

    // real examples
    //compile 'com.mod-buildcraft:buildcraft:6.0.8:dev'  // adds buildcraft to the dev env
    //compile 'com.googlecode.efficient-java-matrix-library:ejml:0.24' // adds ejml to the dev env

    // for more info...
    // http://www.gradle.org/docs/current/userguide/artifact_dependencies_tutorial.html
    // http://www.gradle.org/docs/current/userguide/dependency_management.html
    compile files('lib/industrialcraft-2-2.2.650-experimental-api.jar')
    compile files('lib/DragonAPI 1.7.10 V4c.jar')
    compile files('lib/RotaryCraft 1.7.10 V4c.jar')
}

processResources {
    // this will ensure that this task is redone when the versions change.
    //inputs.property "version", project.version
    //inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    //from(sourceSets.main.resources.srcDirs) {
        //include 'mcmod.info'

        // replace version and mcversion
        //expand 'version':project.version, 'mcversion':project.minecraft.version
    //}

    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task coreJar(type: Jar) {
    baseName = prePend+'HardLib'

    manifest {
        attributes 'FMLCorePlugin': 'com.draco18s.hardlibcore.HardLibCore'
        attributes 'FMLCorePluginContainsFMLMod': 'true'
    }

    from('etc/hardlib') {
        include '*.info'
        expand 'version': libVersion, 'mcversion': project.minecraft.version
    }

    from zipTree(jar.outputs.getFiles().getSingleFile()).matching {
        exclude 'com/draco18s/ores/**', 'com/draco18s/hazards/**', 'com/draco18s/wildlife/**', 'mcmod.info', 'TODO.txt', 'assets/**', 'cog_config/**'
    }
}

task oresJar(type: Jar) {
    baseName = prePend+'HarderOres'

    from('etc/hardores') {
        include '*.info'
        expand 'version': oresVersion, 'mcversion': project.minecraft.version
    }

    from zipTree(jar.outputs.getFiles().getSingleFile()).matching {
        include 'com/draco18s/ores/**', 'assets/ores/**', 'cog_config/**'
        exclude 'cog_config/UndergroundHazards.xml'
    }
}

task hazardsJar(type: Jar) {
    baseName = prePend+'HarderUnderground'

    from('etc/hardunderground') {
        include '*.info'
        expand 'version': hazardsVersion, 'mcversion': project.minecraft.version
    }

    from zipTree(jar.outputs.getFiles().getSingleFile()).matching {
        include 'com/draco18s/hazards/**', 'assets/hazards/**', 'cog_config/UndergroundHazards.xml'
    }
}

task wildlifeJar(type: Jar) {
    baseName = prePend+'HarderWildlife'

    from('etc/hardwildlife') {
        include '*.info'
        expand 'version': wildlifeVersion, 'mcversion': project.minecraft.version
    }

    from zipTree(jar.outputs.getFiles().getSingleFile()).matching {
        include 'com/draco18s/wildlife/**', 'assets/wildlife/**'
    }
}

coreJar.dependsOn('reobf')
oresJar.dependsOn('reobf')
hazardsJar.dependsOn('reobf')
wildlifeJar.dependsOn('reobf')

task releaseJars(type: Copy) {
    from coreJar
    from oresJar
    from hazardsJar
    from wildlifeJar
    rename '-(.*)jar', '.jar'
    rename '-(.*)zip', '.zip'
    into '.'
}

task fullBuild(type: Delete) {
    delete jar
}
fullBuild.dependsOn('releaseJars')