Ejemplo Algoritmo Pseint Ventas-Empleados-Dias

//video disponibles en: https://youtu.be/-1Hf_GwFUH8
Algoritmo arreglo_ventas

	//En un arreglo se tienen registradas las ventas de cinco empleados durante cinco días de la semana.
	//Se requiere determinar de quien fue la venta mayor realizada

	definir aux, i,j, temp, tempsem Como Entero
	dimension ventas[5,5], nombre_empleado[5], dia_semana[5], totalempleado[5]
	//llenar arreglo de nombres
	para i=0 hasta 4
		totalempleado[i]=0 //inicializar el arreglo de acumulacion de ventas
		mostrar "Digite el nombre del empleado número ", i+1
		leer nombre_empleado[i]
	FinPara
	//llenar arreglo de dias
	dia_semana[0]="Lunes"
	dia_semana[1]="Martes"
	dia_semana[2]="Miercoles"
	dia_semana[3]="Jueves"
	dia_semana[4]="Viernes"
	//llenar arreglo de ventas automaticamente
	para i=0 hasta 4
		para j=0 hasta 4
			ventas[i,j]=Aleatorio(1,5)
			//proceso de acumulacion de ventas por empleado
			totalempleado[i]=totalempleado[i]+ventas[i,j]
		FinPara
	FinPara
	//llenar arreglo de ventas manualmente
	//para i=0 hasta 4
		//para j=0 hasta 4
			//mostrar "Digite la cantidad de ventas de " , nombre_empleado[i], " el ", dia_semana[j]
			//leer ventas[i,j]
		//FinPara
	//FinPara

	para i=0 hasta 4
		mostrar "    ", dia_semana[i], "  " Sin Saltar
	FinPara
	mostrar ""
	para i=0 hasta 4

		mostrar nombre_empleado[i], "  " sin saltar
		para j=0 hasta 4
			mostrar ventas[i,j], "            " sin saltar
		FinPara
		mostrar ""
	FinPara

	aux=0

	para i=0 hasta 4
		para j=0 hasta 4


			si ventas[i,j]>aux Entonces
				aux=ventas[i,j]
				temp=i//representa el empleado
				tempsem=j//representa el dia de semana
			FinSi
		FinPara
	FinPara

	mostrar "La venta mayor es ", aux, " que pertenece al empleado ", nombre_empleado[temp]
	//Mostrar el dia de la semana en el cual se dio la venta mayor
	mostrar "El día donde se dio la venta mayor es ",  dia_semana[tempsem]

	//mostrar el total de venta de cada uno de los empleados

	mostrar "las ventas totales de cada empleado son:"
	para i=0 hasta 4
		mostrar nombre_empleado[i], " : " , totalempleado[i]
	FinPara

	//mostrar el total de venta por cada dia de la semana



	//mostrar el total de venta de toda la empresa
	//mostrra el promedio de cada empleado
FinAlgoritmo