# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{10..11} )
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYPI_PN="homeassistant"
inherit distutils-r1 pypi readme.gentoo-r1 systemd

MY_PN=homeassistant

if [[ ${PV} == *9999* ]]; then
        inherit git-r3
        EGIT_REPO_URI="https://github.com/home-assistant/core.git"
        EGIT_BRANCH="dev"
        S="${WORKDIR}/core/"
else
        MY_PV=${PV/_beta/b}
        MY_P=${MY_PN}-${MY_PV}
        SRC_URI="$(pypi_sdist_url)
        https://github.com/home-assistant/core/archive/${MY_PV}.tar.gz -> ${MY_P}.gh.tar.gz"
fi

DESCRIPTION="Open-source home automation platform running on Python."
HOMEPAGE="https://home-assistant.io/ https://git.edevau.net/onkelbeh/HomeAssistantRepository/"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm arm64 x86"
IUSE="systemd +zwave_js"
RESTRICT="!test? ( test )"

# external deps
RDEPEND="${PYTHON_DEPS} acct-group/${MY_PN} acct-user/${MY_PN}
        || ( dev-lang/python:3.10 dev-lang/python:3.11 )
        app-admin/logrotate
        dev-libs/libfastjson
        >=dev-libs/xerces-c-3.1.4-r1"

# make sure no conflicting main Ebuild is installed
RDEPEND="${RDEPEND}
        !app-misc/homeassistant
        !app-misc/homeassistant-full"

# Home Assistant Core dependencies
# from package_constraints.txt
RDEPEND="${RDEPEND}
        <dev-python/pip-23.1"

# Module requirements from useflags
RDEPEND="${RDEPEND}
        zwave_js? ( ~dev-python/pyserial-3.5[${PYTHON_USEDEP}] ~dev-python/zwave-js-server-python-0.48.1[${PYTHON_USEDEP}] )"

BDEPEND="
        dev-python/setuptools[${PYTHON_USEDEP}]"

INSTALL_DIR="/opt/${MY_PN}"

DISABLE_AUTOFORMATTING=1
DOC_CONTENTS="
The HA interface listens on port 8123
hass configuration is in: /etc/${MY_PN}
daemon command line arguments are configured in: /etc/conf.d/${MY_PN}
logging is to: /var/log/${MY_PN}/{server,errors,stdout}.log
The sqlite db is by default in: /etc/${MY_PN}
support at https://git.edevau.net/onkelbeh/HomeAssistantRepository
"

DOCS="README.rst"

src_prepare() {
        if use test ; then
                cp -r ${WORKDIR}/core-${MY_PV}/tests ${S}
        fi
        distutils-r1_src_prepare
}

python_install_all() {
        dodoc ${DOCS}
        distutils-r1_python_install_all
        keepdir "$INSTALL_DIR"
        keepdir "/etc/${MY_PN}"
        fowners -R "${MY_PN}:${MY_PN}" "/etc/${MY_PN}"
        keepdir "/var/log/${MY_PN}"
        fowners -R "${MY_PN}:${MY_PN}" "/var/log/${MY_PN}"
        newconfd "${FILESDIR}/${MY_PN}.conf.d" "${MY_PN}"
        newinitd "${FILESDIR}/${MY_PN}.init.d" "${MY_PN}"
        use systemd && systemd_dounit "${FILESDIR}/${MY_PN}.service"
        dobin "${FILESDIR}/hasstest"
        insinto /etc/logrotate.d
        newins "${FILESDIR}/${MY_PN}.logrotate" "${MY_PN}"
        readme.gentoo_create_doc
}

pkg_postinst() {
        readme.gentoo_print_elog
}

distutils_enable_tests pytest