Auto Gui Control

#SingleInstance,Force
Control_List:=["Text","Edit","UpDown","Picture","Button","Checkbox"
,"Radio","DropDownList","ComboBox","ListBox","ListView","TreeView","Link"
,"Hotkey","DateTime","MonthCal","Slider","Progress","GroupBox","Tab3","StatusBar","ActiveX"]
X_Pos:=10,Y_Pos:=10,Clip_Lock:=0,Row_Counter:=0,Control_Counter:=0
Gui,1:+AlwaysOnTop
Gui,1:Color,555555,Black
Gui,1:Font,cWhite s10 Bold Q5, Segoe UI Black
Gui,1:Add,GroupBox,x10 y5 w270 h60  Center Section ,Control Types
k:=0,temp_list:=""
for,i,j in Control_List
    {
        if(i=1)
            temp_list.= j "||"
        else
            temp_list.= j "|"
    }
Gui,1:Add,DDl,xs+25 ys+25 w220 r15 AltSubmit vDDL_Item gSubmit_All,% temp_List
Gui,1:Add,GroupBox,x10 y70 w270 h60  Center Section ,Options
Gui,1:Add,Edit,xs+10 ys+25 w250 r1 vOptions gSubmit_All
Gui,1:Add,GroupBox,x10 y135 w270 h90  Center Section ,Amount
Gui,1:Add,Radio,xs+10 ys+25 w70 Checked Group vAdd_Amount gSubmit_All,Add 1
Gui,1:Add,Radio,x+10  w70  gSubmit_All,Add 5
Gui,1:Add,Radio,x+10  w70  gSubmit_All,Add 10
Gui,1:Add,Radio,xs+50 yp+30 w70  gSubmit_All,Add ->
Gui,1:Add,Edit,x+10 yp-2 w50 readonly
Gui,1:Add,UpDown, vVar_Amount gSubmit_All Range1-25,2
Gui,1:Add,Groupbox,x10 y230 w270 h100 Center Section ,Text && Position
Gui,1:Add,Text,xs+10 ys+25 w250 h70 BackgroundTrans center,This is the "Light" Version of the auto insert Gui Tool To get Position and size options get the other version.
Gui,1:Add,GroupBox,x10 y330 w270 h90  Center Section ,Output
Gui,1:Add,CheckBox,xs+20 ys+25 vClip_Lock gUnlock_Clip,Unlock Clip
Gui,1:Add,Text,xs+10 yp+25,Name:
Gui,1:Add,Edit,x+10 w60 r1 vGui_Name gSubmit_All ,1
Gui,1:Add,Button,xs+140 ys+30 w110 h40 Disabled vClipBoard_Button gAdd_Controls_To_Clipboard,Clipboard
Gui,1:Show,,Hellbent's Auto Control
Gui,1:Submit,NoHide
return
GuiClose:
    ExitApp
Submit_All:
    Gui,1:Submit,NoHide
    return
Unlock_Clip:
    Gui,1:Submit,NoHide
    GuiControl,1:Enable,ClipBoard_Button
    return
Add_Controls_To_Clipboard:
    Gui,1:Submit,NoHide
    GuiControl,1:Disable,ClipBoard_Button
    GuiControl,1:,Clip_Lock,0
    Final_Output:=""
    if(Add_Amount=1)
        loop_count:=1
    else if(Add_Amount=2)
        loop_count:=5
    else if(Add_Amount=3)
        loop_count:=10
    else if(Add_Amount=4)
        loop_count:=Var_Amount
    Loop % loop_count
        {
            Control_Counter++
            Final_Output.= "Gui," GUI_Name ":Add," Control_List[DDL_Item] ",x" X_Pos " y" Y_Pos " w40 h40 " Options " v"Control_List[DDL_Item] "_" Control_Counter  " ,`n"
            x_pos+=60
            Row_Counter++
            if(Row_Counter=10)
                Row_Counter:=0,x_Pos:=10,y_Pos+=60
        }
    Clipboard:= % Final_Output
    return
*^ESC::ExitApp