permafrost-git

pkgname=permafrost-git
pkgver=r3.f018530
pkgrel=1
pkgdesc="Lightweight single-site browser generator using Webview or Chrome/Chromium."
arch=('x86_64')
url="https://gitea.arsenm.dev/Arsen6331/permafrost"
license=('GPL3')
depends=('webkit2gtk')
makedepends=('git' 'go' 'libglvnd' 'libxcursor' 'libxi' 'libxinerama' 'libxrandr')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://gitea.arsenm.dev/Arsen6331/permafrost.git')
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    # Prevent creation of a `go` directory in one's home.
    # Sometimes this directory cannot be removed with even `rm -rf` unless
    # one becomes root or changes the write permissions.
    export GOPATH="$srcdir/gopath"
    go clean -modcache
}

build() {
    cd "$srcdir/${pkgname%-git}"
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
    make

    # Clean mod cache for makepkg -C
    go clean -modcache
}

package() {
    cd "$srcdir/${pkgname%-git}"
    make PREFIX="$pkgdir" install
}