//===== rAthena Script =======================================
// Eden Group Quests - Mission [11 - 25]
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.2
//===== Compatible With: =====================================
//= rAthena SVN
//===== Description: =========================================
//= Repetable Quests for Players between Baselevel 11 - 25.
//===== Additional Comments: =================================
//= 1.0 First Version.
//= 1.1 Some little optimization here and there. [Masao]
//= 1.2 Optimized. [Euphy]
//============================================================

moc_para01,36,38,3	script	Mission [11 - 25]#Tuto	857,{
	if (countitem(6219) < 1) {
		mes "- Você presisa ter um";
		mes "- ^4d4dff'A marca do Grupo eden'^000000 -";
		mes "para recebe nossas missões.";
		close;
	}
	for(set .@i,11124; .@i<11134; set .@i,.@i+1)
		if (checkquest(.@i,PLAYTIME) == 2) erasequest .@i;
	for(set .@i,11114; .@i<11123; set .@i,.@i+1) {
		set .@j, checkquest(.@i,HUNTING);
		if (.@j == 2) {
			mes " - Você deve recolher sua";
			mes " - Recompesa antes de iniciar";
			mes " - uma nova missão.";
			mes " ";
			mes " - com o Diretor : Spike.";
			close;
		}
		else if (.@j >= 0) {
			mes " - Você só pode pedir";
			mes " - uma missão em um certo tempo - ";
			mes " ";
			mes " - ao Diretor : Spike - ";
			close;
		}
	}
	if (BaseLevel < 11) {
		mes " - Não há tarefas";
		mes " - Abertas para você nesse momento - ";
		close;
	}
	if (BaseLevel > 25) {
		mes " - Estas missões são muito - ";
		mes " - Fácieis para o sua pessoa - ";
		mes " - Procure missões - ";
		mes " - apropriada para seu nível. - ";
		close;
	}
	mes " - Boletim da Missão-";
	mes " - para Iniciantes. -";
	mes " ";
	mes " - Diretor : Spike -";
	next;
	switch(select("Caça Zangão:Caça Condor:Pernas de Gafanhoto:Caça Talo de verme:Caça Esporo:Controle de Peste:Caça Muka:Caça Familiar:Coletar Penas:Coleta Esposos Venenosos:Cancel")) {
		case 1: callsub L_Quest,11114,"Caça Zangão"," - Caça 10 ^4d4dff'Zangão'^000000 - "," - noroeste de Prontera. - ";
		case 2: callsub L_Quest,11115,"Caça Condor"," - Caça 20 ^4d4dff'Condor'^000000 - "," - sul de Morroc. - ";
		case 3: callsub L_Quest,11116,"Pernas de Gafanhoto"," - Caça 10 ^4d4dff'Rocker'^000000 - "," - Sudoeste de Prontera and - "," - trazer 10 ^4d4dffPernas de Gafanhoto^000000. - ";
		case 4: callsub L_Quest,11117,"Caça Talo de verme"," - Caça 20 ^4d4dff'Talo de Verme'^000000 - "," - Sudeste de Payon.- ";
		case 5: callsub L_Quest,11118,"Caça Esporo"," - Caça 30 ^4d4dff'Esporo'^000000 - "," - Em torno de Payon. - ";
		case 6: callsub L_Quest,11119,"Controle de Pernas"," - Caça 20 ^4d4dffOVo de besouro ladrão^000000 - "," - Esgoto de Prontera - "," - trazer 10 ^4d4dffChrysalis^000000. - ";
		case 7: callsub L_Quest,11120,"Caça Muka"," - Caça 20 ^4d4dff'Muka'^000000 - "," - south of Prontera. - ";
		case 8: callsub L_Quest,11121,"Caça Familiar"," - Caça 20 ^4d4dffFamiliar^000000 - "," - Caverna de Payon - "," - oeste de Prontera. - ";
		case 9: callsub L_Quest,11122,"Coletar penas"," - Caça 30 ^4d4dff'Peco Pecos'^000000 - "," - Sul de  Prontera. - ";
		case 10: callsub L_Quest,11123,"Coletar Esporo Venenoso"," - Caça 30 ^4d4dffEsporo venenoso^000000 - "," - Torre de Geffen - "," - trazer 5 ^4d4dffEsporo Venenoso^000000. - ";
		case 11: mes " - Para de Ler o Boletim - "; close;
	}
	end;
L_Quest:
	if (checkquest(getarg(0),PLAYTIME) == 1) {
		mes " - Missão ^4d4dff"+getarg(1)+"^000000 - ";
		mes " - Já está pronta para hoje - ";
		mes " ";
		mes " - Diretor : Spike - ";
		close;
	}
	mes " - Missão '"+getarg(1)+"' - ";
	for(set .@i,2; .@i<getargcount(); set .@i,.@i+1)
		mes getarg(.@i);
	mes " ";
	mes " - Diretor : Spike - ";
	next;
	if(select("Eu vou fazer esta missão:Olhar outras missões.") == 2) {
		mes " - Vamos para a pesquisa -";
		mes " - outras missões. - ";
		close;
	}
	for(set .@i,2; .@i<getargcount(); set .@i,.@i+1)
		mes getarg(.@i);
	if (getarg(0) == 11123 && checkquest(11123,PLAYTIME) == 2)
		erasequest 11133;	// Special case for "Collect Poison Spores"
	setquest getarg(0);
	close;
}

moc_para01,32,30,6	script	Spike	914,{
	for(set .@i,11114; .@i<11124; set .@i,.@i+1) {
		set .@j, checkquest(.@i,HUNTING);
		if (.@j == 2) switch(.@i) {
			case 11114: callsub L_Quest,.@i,"Caça Zangão",900;
			case 11115: callsub L_Quest,.@i,"Caça condor",1800;
			case 11116: callsub L_Quest,.@i,"Pernas de Gafanhoto",1400,940,10;
			case 11117: callsub L_Quest,.@i,"Caça talo de Verme",2600;
			case 11118: callsub L_Quest,.@i,"Caça Esporo",3900;
			case 11119: callsub L_Quest,.@i,"Controle de Pragas",2900,915,10;
			case 11120: callsub L_Quest,.@i,"Caça MUKA",3200;
			case 11121: callsub L_Quest,.@i,"Caça Familiar",3200;
			case 11122: callsub L_Quest,.@i,"Coletar Penas",5400;
			case 11123: callsub L_Quest,.@i,"Coletar Esporo Venenoso",6000,7033,5;
		}
		else if (.@j >= 0) {
			mes "[Spike]";
			mes "Você não terminou sua missão ainda.";
			mes "Mantenha sempre o bom trabalho. Você está quase no fim.";
			close;
		}
	}
	mes "[Spike]";
	mes "Você está procurando um emprego";
	mes "nós sempre temos muito trabalho a ser realizado.";
	next;
	mes "[Spike]";
	mes "Por que você não olhar em volta e encontrar algumas tarefas bem interessantes?";
	close;
L_Quest:
	if (checkquest(getarg(0),HUNTING) == 2) {
		if (getarg(3,0))
			if (countitem(getarg(3)) < getarg(4)) {
				mes "[Spike]";
				mes "Você não tem o suficiente "+getitemname(getarg(3))+".";
				mes "Você prescisa trazer"+getarg(4)+" "+getitemname(getarg(3))+".";
				close;
			}
		mes "[Spike]";
		mes "Hmm... Deixe-me ver!";
		mes "Você concluiu o '"+getarg(1)+"' missão.";
		next;
		mes "[Spike]";
		mes "Bom trabalho!!";
		mes "O nosso cliente está tão feliz com seu trabalho. Ele vai apreciar oque você fez.";
		mes "Por favor, ajude-nos outra vez.Obrigado!";
		if (getarg(3,0)) delitem getarg(3),getarg(4);
		erasequest getarg(0);
		setquest getarg(0)+10;
		getexp getarg(2),0;
		close;
	}
}