allprojects {
    ext.artifactGroup = 'com.integer.oncomed'
    ext.artifactVersion = '0.2'
    ext.isSnapshot = true
    ext.copyright = 'Copyright (c) $today.year Integer Ltd. All Rights Reserved.'
    //tomcatDir = rootDir.absolutePath + '/../tomcat'

	ext.repositoryUrl = "http://localhost:8081/nexus/content/"
    ext.repositoryUser = 'admin'
    ext.repositoryPassword ='admin123'
}

buildscript {
    ext.cubaPlugin = [group: 'com.haulmont.gradle', name: 'cuba-plugin', version: '1.4.12']

    repositories {
        mavenLocal()
        mavenCentral()
  maven {
            credentials {
                username 'admin'
                password 'admin123'
            }
            url "http://localhost:8081/nexus/content/groups/work/"
        }
    }
    dependencies {
        classpath cubaPlugin
    }
}

def cubaVersion = '3.5.4'

def globalModule = project(':oncomed-global')
def coreModule = project(':oncomed-core')
def guiModule = project(':oncomed-gui')
def webModule = project(':oncomed-web')

def postgres = 'postgresql:postgresql:9.1-901.jdbc4'
def servletApi = 'org.apache.tomcat:servlet-api:6.0.20'

def cubaWeb = "com.haulmont.cuba:cuba-web:$cubaVersion"

def coreJarNames = ['bali', 'chile-core', 'chile-jpa', 'cuba-global', 'cuba-core',
                'oncomed-global', 'oncomed-core']

apply(plugin: 'idea')
apply(plugin: 'cuba')

configure([globalModule, coreModule, guiModule, webModule]) {
    apply(plugin: 'java')
    apply(plugin: 'idea')
    apply(plugin: 'maven')
    apply(plugin: 'cuba')

    configurations.each {
        it.resolutionStrategy.cacheChangingModulesFor 2, "minutes"
    }

    dependencies {
        compile("com.haulmont.cuba:cuba-global:$cubaVersion")
        compile('axis:axis:1.4')
        compile group: 'javax.mail', name: 'mail', version: '1.4'
        compile group: 'javax.xml.rpc', name: 'javax.xml.rpc-api', version: '1.1.1'
        compile group: 'org.apache.directory.studio', name: 'org.apache.commons.logging', version: '1.1.3'
        compile group: 'commons-discovery', name: 'commons-discovery', version: '0.4'
        compile group: 'wsdl4j', name: 'wsdl4j', version: '1.6.2'

        testCompile('junit:junit:4.5')
    }

    task sourceJar(type: Jar) {
        from file('src')
        classifier = 'sources'
    }

    artifacts {
        archives sourceJar
    }
}

configure(globalModule) {
    dependencies {
        provided(cubaPlugin)
    }
    task enhance(type: CubaEnhancing) {
        persistenceXml = "$globalModule.projectDir/src/oncomed-persistence.xml"
        metadataXml = "$globalModule.projectDir/src/oncomed-metadata.xml"
    }
    compileJava << {
        enhance.execute()
    }
}

configure(coreModule) {

    configurations {
        jdbc
        dbscripts
    }

    dependencies {
        compile(globalModule)
        compile("com.haulmont.cuba:cuba-core:$cubaVersion")
        compile('axis:axis:1.4')
        compile group: 'javax.mail', name: 'mail', version: '1.4'
        compile group: 'javax.xml.rpc', name: 'javax.xml.rpc-api', version: '1.1.1'
        compile group: 'org.apache.directory.studio', name: 'org.apache.commons.logging', version: '1.1.3'
        compile group: 'commons-discovery', name: 'commons-discovery', version: '0.4'
        compile group: 'wsdl4j', name: 'wsdl4j', version: '1.6.2'

        testCompile("com.haulmont.cuba:cuba-core:$cubaVersion:tests")
        testCompile('junit:junit:4.5')
        testCompile("com.haulmont.cuba:cuba-shared-lib:$cubaVersion")

        provided(servletApi)
        jdbc(postgres)
        testRuntime(postgres)

        dbscripts("com.haulmont.cuba:cuba-core:$cubaVersion:db@zip")
    }

    test {
        scanForTestClasses = false
        includes = ['**/*Test.class']
    }

    task deploy(dependsOn: assemble, type: CubaDeployment) {
        appName = 'app-core'
        jarNames = coreJarNames
    }

    task createDb(dependsOn: assemble, description: 'Creates local Postgres database', type: CubaDbCreation) {
        dbms = 'postgres'
        dbName = 'oncomed'
        dbUser = 'root'
        dbPassword = 'root'
    }

    task createTestDb(dependsOn: assemble, description: 'Creates local Postgres database for tests', type: CubaDbCreation) {
        dbms = 'postgres'
        dbName = 'oncomed_test'
        dbUser = 'root'
        dbPassword = 'root'
    }
}

configure(guiModule) {
    dependencies {
        compile(globalModule)
        compile(group: 'com.haulmont.cuba', name: 'cuba-gui', version: cubaVersion)
    }
}

configure(webModule) {
    configurations {
        webcontent
    }

    dependencies {
        compile(globalModule)
        compile(guiModule)
        compile(cubaWeb)

        webcontent(group: 'com.haulmont.cuba', name: 'cuba-web', version: cubaVersion, classifier: 'web', ext: 'zip')
    }

    task webArchive(type: Zip) {
        from file('web')
        classifier = 'web'
    }

    artifacts {
        archives webArchive
    }

    task deploy(dependsOn: assemble, type: CubaDeployment) {
        appName = 'app'
        appJars('bali', 'chile-core', 'chile-jpa', 'cuba-global', 'cuba-client', 'cuba-gui', 'cuba-web',
                'oncomed-global', 'oncomed-gui', 'oncomed-web')
    }
}

task restart(dependsOn: ['stop', ':oncomed-core:deploy', ':oncomed-web:deploy'], description: 'Redeploys applications and restarts local Tomcat') << {
    ant.waitfor(maxwait: 6, maxwaitunit: 'second', checkevery: 2, checkeveryunit: 'second') {
        not {
            socket(server: 'localhost', port: '8787')
        }
    }
    start.execute()
}