Flashall_nosystem.bat

@ECHO OFF
:PrepColor
REM Required for :Color
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
  set "DEL=%%a"
)
GOTO :Header

:Header
REM Color Header to T-Mobile color for FLAIR
CALL :Color 7D "TMO Moto Z2 Force 27.1.5 (March Edition) Flashall by rcmaehl @ XDA"
ECHO.
GOTO :Disclaimer

:Disclaimer
CALL :Color 40 "=================================DISCLAIMER!================================="
CALL :Color 40 "FLASH AT YOUR OWN RISK!! NOT RESPONSIBLE FOR DAMAGES IF THIS STUFF GOES SOUTH"
CALL :Color 40 "IF YOU DO NOT KNOW WHAT A FLASHALL, TWRP, OR FASTBOOT ARE, YOU ARE LIKELY NOT"
CALL :Color 40 "READY FOR THIS SCRIPT!         OTHERWISE, FULLY READ ALL MESSAGES AND PROCEED"
CALL :Color 40 "=================================DISCLAIMER!================================="
ECHO.
GOTO :DetectNotWin7

:DetectNotWin7
for /f "tokens=4-5 delims=. " %%i in ('ver') do set VER1=%%i
for /f "tokens=4-5 delims=. " %%i in ('ver') do set VER2=%%j
IF %VER1% EQU 6 IF %VER2% GTR 1 GOTO :NotWin7Warning
if %VER1% GTR 6 GOTO :NotWin7Warning
GOTO :LogoPrompt

:NotWin7Warning
CALL :Color 60 "===================================ALERT!!==================================="
CALL :Color 60 "YOU ARE USING WINDOWS 8 OR NEWER. DUE TO LOW LEVEL CHANGES, YOU MAY ENCOUNTER"
CALL :Color 60 "VARIOUS ERROR MESSAGES, SUCH AS THE ONES YOU SEE BELOW. THIS IS A KNOWN ISSUE"
CALL :Color 60 "PLEASE REFER TO THE XDA THREAD FOR POTENTIAL SOLUTIONS IF YOU ENCOUNTER THESE"
CALL :Color 60 "===================================ALERT!!==================================="
ECHO.
ECHO [EXAMPLE] (bootloader) slot-suffi: not found [/EXAMPLE]
ECHO [EXAMPLE] FAILED (remote: unknown command)   [/EXAMPLE]
ECHO.
SET /P "TestADB=Would you like to test your PC before flashing (Y/N)? "
IF /I "%TestADB%" EQU "Y" GOTO :WindowsTest
CALL :Color 06 "Windows Compatibility Testing Skipped."
GOTO :LogoPrompt

:WindowsTest
ECHO Press any key to boot into fastboot and begin testing...
PAUSE
adb reboot bootloader
fastboot oem fb_mode_set
fastboot getvar all > getvar
fastboot oem fb_mode_clear
ECHO.
REM TODO: Automate this with a log file
SET /P "Result=Did you receive any error messages (Y/N)? "
IF /I "%Result%" EQU "N" GOTO :LogoPrompt
GOTO :SeeXDA

:SeeXDA
CALL :Color 60 "===================================ALERT!!==================================="
CALL :Color 60 "YOU INDICATED THAT THE ADB TEST FAILED FOR FLASHALL.  DO NOT ATTEMPT TO FORCE"
CALL :Color 60 "THIS SCRIPT TO FLASH THE DEVICE IF THE TEST FAILED OR DATA LOSS _WILL_ OCCUR!"
CALL :Color 60 "PLEASE REFER TO THE XDA THREAD FOR POTENTIAL SOLUTIONS IF YOU ENCOUNTER THESE"
CALL :Color 60 "===================================ALERT!!==================================="
GOTO :EOF

:LogoPrompt
SET /P "logofix=Replace Bootloader Unlocked Warning (Y/N)? "
IF /I "%logofix%" EQU "Y" GOTO :LogoRename
CALL :Color 06 "Bootloader Unlocked Warning Replacement Skipped."
ECHO.
GOTO :FlashPrompt

:LogoRename
move logo.bin logo_original.bin
CALL :Color 0A "Renamed logo.bin to logo_original.bin"
move logo_fix_white.bin logo.bin
CALL :Color 0A "Renamed logo_fix_white.bin to logo.bin"
GOTO :FlashPrompt

:FlashPrompt
ECHO Press any key to boot into fastboot and begin flashing...
PAUSE
GOTO :Flash

:Flash
adb reboot bootloader
fastboot getvar max-sparse-size
fastboot oem fb_mode_set
fastboot flash partition gpt.bin
fastboot flash bootloader bootloader.img
fastboot flash modem NON-HLOS.bin
fastboot flash fsg fsg.mbn
fastboot flash bluetooth BTFM.bin
fastboot flash dsp adspso.bin
fastboot flash logo logo.bin
fastboot flash boot boot.img
fastboot flash gpt gpt.bin
fastboot flash oem oem.img
fastboot erase modemst1
fastboot erase modemst2
fastboot erase carrier
fastboot erase cache
fastboot erase ddr
fastboot flash fsg fsg.mbn
fastboot flash bluetooth BTFM.bin
fastboot oem fb_mode_clear
GOTO :Done

:Done
CALL :Color A0 "============================================================================="
CALL :Color A0 "Finished.          Check Output for Errors.          Press any key to reboot."
CALL :Color A0 "============================================================================="
PAUSE

:Reboot
fastboot reboot
GOTO :EOF

:Color
@ECHO OFF
echo %DEL% > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1
GOTO :EOF