xkcd 1017

#SingleInstance force
seasons := {0: "Winter", 1: "Autumn", 2: "Summer", 3: "Spring"}

GUI font, s9, Segoe UI
GUI add, DateTime, vFrom, yyyy-MM-dd HH:mm:ss
GUI add, DateTime, vTo x+5 yp Choose20150611130000, yyyy-MM-dd HH:mm:ss
Gui Add, Progress, w600 h20 xm y+5 c00CC00 vRawProgress Range0-100000
Gui Add, Progress, w600 h20 xm y+0 cCCCC00 vRawProgressMagnified Range0-100000
;Gui Add, Progress, w600 h20 xm y+0 cCC0000 vRawProgressMagnifiedTwice Range0-100000
GUI font, s15, Verdana
GUI add, edit, Center w600 ReadOnly xm y+5 vRawProgressPercent
GUi add, edit, w140 ReadOnly xm y+5 vDispYearNow Right
GUI font, s9, Segoe UI
GUI add, radio, w40 disabled yp x+5 section, Myr
GUI add, radio, w40 disabled xp y+1, kyr
GUI add, radio, w40 disabled ys x+5, BC
GUI add, radio, w40 disabled xp y+1 checked, AD
GUI font, s15, Verdana
GUi add, edit, w140 ReadOnly ys x+5 vDispDateNow Center
GUI font, s9, Segoe UI
GUI add, radio, w40 disabled yp x+5 section checked, date
GUI add, radio, w40 disabled xp y+1, mth
GUI font, s15, Verdana
GUI add, edit, Center w120 ReadOnly ys x+5 vDispTimeNow
GUI font, s9, Segoe UI
GUI add, radio, w40 disabled yp x+5 section checked, time
GUI add, radio, w40 disabled xp y+1, days
GUI font, s9, Segoe UI
GUI font, s15, Verdana
GUi add, edit, w140 ReadOnly xm y+5 vDispYear Right
GUI font, s9, Segoe UI
GUI add, radio, w40 disabled yp x+5 vmyearp section, Myr
GUI add, radio, w40 disabled xp y+1 vkyearp, kyr
GUI add, radio, w40 disabled ys x+5 vbcp, BC
GUI add, radio, w40 disabled xp y+1 vadp checked, AD
GUI font, s15, Verdana
GUi add, edit, w140 ReadOnly ys x+5 vDispDate Center
GUI font, s9, Segoe UI
GUI add, radio, w40 disabled yp x+5 vdtimep section, date
GUI add, radio, w40 disabled xp y+1 vdmonsp, yr
GUI font, s15, Verdana
GUI add, edit, Center w120 ReadOnly ys x+5 vDispTime
GUI font, s9, Segoe UI
GUI add, radio, w40 disabled yp x+5 vttimep section, time
GUI add, radio, w40 disabled xp y+1 vtdaysp, days
GUI add, radio, w40 disabled xp y+1 vtseasp, seas
GUI font, s9, Segoe UI
GUI add, button, xm gReload, Reload
GUI add, button, yp x+5 gRecalculate, Recalculate
GUI Show
SetTimer, SetItems, 1000
Return
Recalculate:
    SetTimer, SetItems, 1000
Return
SetItems:
    GUI submit, NoHide
    now = %A_Now%
    FormatTime, oYear, %now%, yyyy
    FormatTime, oDate, %now%, MMM dd
    FormatTime, oTime, %now%, HH:mm:ss
    GUIControl,, dispYearNow, %oyear%
    GUIControl,, dispDateNow, %oDate%
    GUIControl,, dispTimeNow, %oTime%
    now -= 19700101000000,seconds
    From -= 19700101000000,seconds
    To -= 19700101000000,seconds
    Percentage := (now - from) / (to - from)
    GUIControl,, RawProgress, % Percentage * 100000
    GUIControl,, RawProgressMagnified, % Mod(Percentage * 100000 * 100000, 100000)
    ;GUIControl,, RawProgressMagnifiedTwice, % Mod(Percentage * 1000000 * 10 * 5, 1000000 * 5)
    GUIControl,, RawProgressPercent, % Percentage * 100 "%"
    if Percentage > 1
    {
        MsgBox it's over!
        SetTimer, SetItems, Off
        return
    }
    TimeBackwards := exp(20.3444 * percentage ** 3 + 3) - exp(3)
    if timeBackwards > 1000000
    {
        millionYearsAgo := Round(timeBackwards / 1000000, 2)
        oddMonths := Mod(timeBackwards, 1000)
        oddDays := Floor(Mod(oddMonths, 1) * 4)
        GUIControl,, dispYear, %millionYearsAgo%
        GuiControl,, Myearp, 1
        GuiControl,, dispDate, % "…" Substr("000" floor(OddMonths), -2)
        GuiControl,, dmonsp, 1
        GUIControl,, dispTime, % seasons[oddDays]
        GuiControl,, tseasp, 1

    }
    else if (timeBackwards > 20000)
    {
        yearsAgo := Floor(timeBackwards)
        daysAgo := (timeBackwards - yearsAgo) * 365
        GUIControl,, dispYear, % round(yearsAgo / 1000, 2)
        GUIControl,, kyearp, 1
        GUIControl,, dispDate, and
        GUIControl,, dispTime, % Floor(daysAgo)
        GUIControl,, tdaysp, 1
    }
    else if (timeBackwards > 400)
    {
        years := A_Year - Floor(timeBackwards)
        if (years < 0)
        {
            years *= -1
            GuiControl,, bcp, 1
            GUIcontrol,, DispYear, %years%
        }
        else
        {
            GuiControl,, adp, 1
            GUIcontrol,, DispYear, %years%
        }
        now = %A_Now%
        yearsBack := -(timeBackwards - floor(timeBackwards)) * 365
        EnvAdd now, %yearsBack%, days
        FormatTime, oDate, %now%, MMM dd
        FormatTime, oTime, %now%, HH:mm:ss
        GUIControl,, dispYear, %years%
        GUIControl,, dispDate, %oDate%
        GUIControl,, dispTime, %oTime%
        GUIControl,, ttimep, 1
    }
    else {
        yearsBack := -timeBackwards * 365
        now = %A_Now%
        EnvAdd now, %yearsBack%, days
        ;ToolTip %now%
        FormatTime, oY, %now%, yyyy
        FormatTime, oDate, %now%, MMM dd
        FormatTime, oTime, %now%, HH:mm:ss
        GUIControl,, dispYear, %oY%
        GUIControl,, dispDate, %oDate%
        GUIControl,, dispTime, %oTime%
        GUIControl,, adp, 1
        GUIControl,, ddatep, 1
        GUIControl,, ttimep, 1
    }
Return

Reload:
Reload
Return

GuiClose:
ExitApp