Hangman - UI (standalone) v1.12

_hgm_guesslist = [ // FEEL FREE TO ADD MORE WORDS TO THE LIST
    PENCIL CLOCKWERK MATTRESS AUTOMOBILE AIRPLANE CELLPHONE
    PRINTER TISSUE MONITOR IRONMAN AWAKENING REALITY
    COMPROMISE CONTROLLER IMPOSSIBILITY KEYCHAIN DEMISE
    PRINTER DRAWER PIPELINE CURTAIN SAMSUNG TRASHCAN
    REPLICATE CONDITIONER DEODORANT FRAMEWORK DESTRUCTION
    EXPLOSION ARTILLERY FACEBOOK FOLDER ARISTOCRAT
    "THE GAME" "TRY YOUR LUCK" "CHICKEN NUGGETS"
]

_hgm_buildword = [
    _hgm_guessword = ""
    loop c (strlen $_hgm_rndword) [
        c = (substr $_hgm_rndword $c 1)
        _hgm_guessword = (concatword $_hgm_guessword (if (
            || [=s $c (substr $_hgm_rndword 0 1)] [>= (strstr $arg1 $c) 0]
        ) [ result $c ] [ ? (=s $c " ") " " "_" ]))
    ]
]

_hgm_charset = [
    A B C D E F G
    H I J K L M N
    O P Q R S T U
    V W X Y Z
]

_hgm_reset = [
    local n ; n = (listdel $_hgm_guesslist (getalias _hgm_rndword))
    _hgm_wrong = ""
    _hgm_right = ""
    _hgm_triesleft = 6
    _hgm_guessword = ""
    _hgm_rndword = (at $n (rnd (listlen $n)))
    if (> (strlen $_hgm_rndword) 13) [
        _hgm_size = (*f (strlen $_hgm_rndword) 0.032)
    ] [ _hgm_size = 0.42 ]
    _hgm_buildword
]

hangman = [ showui "hangman" ]

//=======================================================================================//

newui "hangman" [
    uicolor 0xF0E8E4 0 0 [
        uispace 0.01 0.01 [
            uivlist 0.016 [
                uifill 0 0 [
                    local h ; h = (uihover?)
                    uimodcolor 0xFFFFFF 0 0 [
                        uiclamp 1 1 1 1
                        uirelease [ _hgm_reset ]
                    ]
                    uivlist 0.008 [
                        uigroup [
                            uihgradient 0x40D01010 0x4020D020 $_hgm_size 0.01
                            if $_hgm_triesleft [
                                uiclip (*f $_hgm_triesleft (divf $_hgm_size 6)) 0.01 [
                                    uialign -1 0
                                    uihgradient 0xD01010 0x20D020 $_hgm_size 0.01
                                ]
                            ]
                            uioutline 0x808080 $_hgm_size 0.01
                            uispace 0.01 0 [
                                uiclamp 1 1
                                cond $h [
                                    uitext "NEW GAME" 0.65
                                ] (! $_hgm_triesleft) [
                                    uitext "^f3FAILURE" 0.65
                                ] (=s $_hgm_guessword $_hgm_rndword) [
                                    uitext "^f0SUCCESS" 0.65
                                ]
                                uialign- 1
                                uitext "HP" 0.65
                                uialign- -1
                            ]
                        ]
                        uihlist 0.032 [
                            looplist i $_hgm_guessword [
                                uioutline 0x808080 0 0 [
                                    uihlist 0 [
                                        local l1 l2 ll
                                        loop l (strlen $i) [
                                            ll = (+ 1 $l)
                                            l1 = (substr $i $l 1)
                                            l2 = (substr $i $ll 1)
                                            uifill 0.032 0.04 [
                                                if (<s $l1 "_") [
                                                    uimodcolor 0xEFEFEF
                                                    uiclamp- 1 1 1 1
                                                ]
                                                uitext $l1 0.75
                                            ]
                                            if (< $ll (strlen $i)) [
                                                if (^ (<s $l1 "_") (<s $l2 "_")) [
                                                    uiline 0x808080
                                                    uiclamp- 0 0 1 1
                                                ]
                                            ]
                                        ]
                                    ]
                                ]
                            ]
                        ]
                    ]
                ]
                uiline 0x808080
                uiclamp- 1 1
                uivlist 0 [
                    uigrid 7 0 [
                        looplist p (concat $_hgm_charset "?") [
                            uifill 0.06 0.04 [
                                if (< (strstr $_hgm_guessword $p) 0) [
                                    if (|| [=s $_hgm_guessword $_hgm_rndword] [> (strstr $_hgm_wrong $p) 0]) [
                                        uicolortext $p 0x40FFFFFF 0.8
                                    ] [
                                        uimodcolor 0xFFFFFF
                                        uihover [
                                            uimodcolor 0xEFEFEF
                                            uioutline 0x808080
                                            uihold [ uimodvgradient 0xDFDFDF 0xFFFFFF ] [
                                                uimodvgradient 0xFFFFFF 0xDFDFDF
                                            ]
                                        ]
                                        uiclamp* 1 1 1 1
                                        uitext $p 0.8
                                        if (=s "?" $p) [
                                            local n ; n = (listdel $_hgm_charset $_hgm_wrong $_hgm_right)
                                            p = (at $n (rnd (listlen $n)))
                                        ]
                                        uirelease [
                                            if (< (strstr $_hgm_rndword $p) 0) [
                                                _hgm_triesleft = (- $_hgm_triesleft 1)
                                                if $_hgm_triesleft [
                                                    _hgm_wrong = (concat $_hgm_wrong $p)
                                                ] [ _hgm_buildword $_hgm_rndword ]
                                            ] [
                                                _hgm_right = (concat $_hgm_right $p)
                                                _hgm_buildword $_hgm_right
                                            ]
                                        ]
                                    ]
                                ] [
                                    uimodcolor 0xEFEFEF
                                    uioutline 0x808080
                                    uiclamp* 1 1 1 1
                                    uicolortext $p 0x80FF80 0.8
                                ]
                            ]
                        ]
                    ]
                ]
            ]
            uicolortext "v1.12" 0x80FFFFFF 0.55
            uialign- 1 1
        ]
    ]
    uioutline 0x808080
    uiclamp- 1 1 1 1
] [ _hgm_reset ]