Super Factory Manager for Ars Nouveau

name "Ars Nouveau"

-- Source Gem creation
every 20 ticks do
    input *lapis* from buffer1
    output to imbuement_chamber
end

-- Put ingredients for the craft on pedestals and into the imbuement chamber
every 20 ticks do
-- put everything BUT source gems from the buffer onto the pedestals
    input except *gem* from buffer1
    output to imbuement_pedestal
    forget
-- THEN put the source gem into the imbuement chamber
    input *gem* from buffer1
    output to imbuement_chamber
end

-- Take finished crafts from the imbuement chamber
every 20 ticks do
    if imbuement_pedestal has < 1 item:: then
-- if pedestals are empty we are crafting source gems
-- take those from the imbuement chamber
        input *gem* from imbuement_chamber
        output to provider1
    else
-- if pedestals are not empty we are crafting something else
-- take everything BUT source gems from the imbuement chamber
        input except *gem* from imbuement_chamber
        output to provider1
    end
end

-- crafting e.g. essences does not use up the materials on the pedestals
-- so clean up after finishing the craft
every 20 ticks do
    if imbuement_chamber has < 1 item:: and buffer1 has < 1 item:: then
        input from imbuement_pedestal
        output to provider1
    end
end

-- Put crafting ingredients onto pedestal and into enchanting apparatus
-- same as for the imbuement chamber
every 20 ticks do
    input except *gem* from buffer2
    output to enchanting_pedestal
    forget
    input *gem* from buffer2
    output to enchanting_apparatus
end

-- Take the finished craft from the enchanting apparatus
every 20 ticks do
    if enchanting_pedestal has < 1 item:: then
        input from enchanting_apparatus
        output to provider2
    end
end

-- Since crafting with the enchanting apparatus does use up all ingredients
-- there is no need to clean up afterwards