@echo off
for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %COMPUTERNAME% ^| findstr [') do set NETWORKIP=%%a

FOR /f "tokens=2,* delims= " %%a in ('IPCONFIG ^/ALL ^| FINDSTR "Primary Dns"') do set tempsuffix=%%b
FOR /f "tokens=1,2 delims=:" %%a in ('echo %tempsuffix%') do set dnssuffix=%%b
SET FQDN=%COMPUTERNAME%
if "%DNSSUFFIX:~1%" neq "" SET FQDN=%COMPUTERNAME%.%DNSSUFFIX:~1%

set servernaam=%COMPUTERNAME%
set serverip=%NETWORKIP%
set serverfqdn=%FQDN:~0,-1% REM remove trailing whitespace

set ssl_ou=GIS^&ICT
set ssl_o=Sweco
set ssl_l=Rotterdam
set ssl_st=Zuid-Holland
set ssl_c=NL

echo Server name: %servernaam%
echo Network IP: %serverip%
echo FQDN: %serverfqdn%


set PATH="C:\Program Files\Java\jdk1.8.0_172\bin\";%PATH%

keytool -genkey ^
-alias %servernaam% ^
-keyalg RSA ^
-keystore server-keystore_tmp.jks ^
-ext san=ip:%serverip%,dns:%serverfqdn%,dns:localhost ^
-validity 3650 ^
-dname "CN=%servernaam%, OU=%ssl_ou%, O=%ssl_o%, L=%ssl_l%, ST=%ssl_st%, C=%ssl_c% " ^
-storepass mulepass -keypass mulepass

keytool -export ^
-alias %servernaam% ^
-keystore server-keystore_tmp.jks ^
-file %servernaam%.cer ^
-storepass mulepass