Inverse Tangent Function Hypixel Housing

// Inputs:
//   for yaw: stat (l1) = z leg, stat (l2) = x leg
//   for pitch: stat (l1) = xz leg, stat (l2) = y leg
// Output: stat @out = angle in Minecraft
// Temps: teamstat _0 placeholderTeam, teamstat _1 placeholderTeam, teamstat _2 placeholderTeam, stat _0, stat _1, globalstat _0, globalstat _1

// Make sure you set "placeholderTeam" to one of the teams in your house

if () {

teamstat _0 placeholderTeam = %stat.player/(l1)%
teamstat _0 placeholderTeam += 4294967296
teamstat _0 placeholderTeam /= 4294967296
teamstat _0 placeholderTeam *= 2
teamstat _0 placeholderTeam -= 1

stat (l1) *= "%stat.team/_0 placeholderTeam%"

teamstat _1 placeholderTeam = %stat.player/(l2)%
teamstat _1 placeholderTeam += 4294967296
teamstat _1 placeholderTeam /= 4294967296
teamstat _1 placeholderTeam *= 2
teamstat _1 placeholderTeam -= 1

stat (l2) *= "%stat.team/_1 placeholderTeam%"

stat _0 = %stat.player/(l1)%
stat _0 -= %stat.player/(l2)%

globalstat _0 = %stat.player/(l2)%
globalstat _0 -= %stat.player/(l1)%
globalstat _0 += 4294967296
globalstat _0 /= 4294967296
globalstat _0 *= %stat.player/_0%
globalstat _0 += %stat.player/(l2)%
globalstat _0 *= %stat.global/_0%
globalstat _0 *= 1000000000
globalstat _0 /= %stat.player/(l2)%
globalstat _0 /= %stat.player/(l1)%

stat _1 = %stat.global/_0%
stat _1 *= %stat.player/_1%

stat @out = %stat.player/_1%
stat @out /= -21507006760
stat @out += 159314220
stat _1 /= 1000000000

}

if () {

stat @out *= %stat.player/_1%
stat @out -= 327622764000000000
stat @out /= 1000000000
stat @out *= %stat.player/_1%
stat @out /= 1000000000
stat @out *= %stat.global/_0%
globalstat _0 *= 1000000000
stat @out += %stat.global/_0%

globalstat _1 = 1570796326794896619
globalstat _1 -= %stat.player/@out%
globalstat _1 -= %stat.player/@out%

teamstat _2 placeholderTeam = %stat.player/(l2)%
teamstat _2 placeholderTeam -= %stat.player/(l1)%
teamstat _2 placeholderTeam += 4294967296
teamstat _2 placeholderTeam /= 4294967296
teamstat _2 placeholderTeam *= %stat.global/_1%

stat @out += "%stat.team/_2 placeholderTeam%"

globalstat _1 = 3141592653589793238
globalstat _1 -= %stat.player/@out%
globalstat _1 -= %stat.player/@out%

teamstat _0 placeholderTeam -= 1
teamstat _0 placeholderTeam /= 2
teamstat _0 placeholderTeam *= %stat.global/_1%
teamstat _0 placeholderTeam -= %stat.player/@out%
teamstat _0 placeholderTeam *= "%stat.team/_1 placeholderTeam%"

stat @out = "%stat.team/_0 placeholderTeam%"
stat @out /= 17453292519943

}