flags:setleader(ADMIN_SIXTH_LEVEL)
cmd:setleader(playerid, const params[])
{
    new targetid;
    if(sscanf(params, "i", targetid))
        return SendHelp(playerid, !"Используйте: {"#cWhite"}/setleader [id игрока]");
    if(!IsPlayerConnected(targetid))
        return SendError(playerid, !"Игрок не в сети!");
    if(!IsPlayerLogged(targetid))
        return SendError(playerid, !"Игрок не авторизован!");
    if(IsPlayerInAnyVehicle(targetid))
        return SendError(playerid, !"Игрок находится в транспорте!");
    if(GetPlayerData(targetid, P_RANG) == MAX_RANGS)
    {
        SetPlayerData(targetid, P_MEMBER, 0);
        SetPlayerData(targetid, P_RANG, 0);
        SetPlayerData(targetid, P_FSKIN, 0);
        SetPlayerData(targetid, P_FWARN, 0);
        SetPlayerSkin(targetid, GetPlayerData(targetid, P_SKIN));
        SetPlayerColor(targetid, GetFractionFullColor(GetPlayerFraction(targetid)));
        format(
            string_64,
            64,
            "{%s}%s [%d]",
            GetFractionColor(GetPlayerFraction(targetid)), GetPlayerNameEx(targetid), targetid
        );
        UpdateDynamic3DTextLabelText(GetPlayerData(targetid, P_NAME_LABEL), -1, string_64);
        string_64[0] = EOS;
        format(
            global_string,
            200,
            "UPDATE `users` SET `MEMBER` = '0', `RANG` = '0', `FSKIN` = '0', `FWARN` = '0' WHERE `ID` = '%i' LIMIT 1",
            GetPlayerData(targetid, P_ID)
        );
        mysql_tquery(dbHandle, global_string);
        global_string[0] = EOS;
        format(
            global_string,
            145,
            "[A] %s %s[%d] снял %s[%d] с поста лидера.",
            GetPlayerAdminName(playerid), GetPlayerNameEx(playerid), playerid, GetPlayerNameEx(targetid), targetid
        );
        SendAdminMessage(ColorGray, global_string);
        global_string[0] = EOS;
        return SendClientMessage(targetid, ColorLightRed, !"Вы были сняты с поста лидера.");
    }
    global_string[0] = EOS;
    for(new idx = 1; idx <= MAX_FRACTIONS; idx++)
    {
        format(
            string_64,
            64,
            "%d. %s\n",
            idx, GetFractionName(idx)
        );
        strcat(global_string, string_64);
        string_64[0] = EOS;
    }
    ShowPlayerDialog(playerid, DIALOG_SET_LEADER, DIALOG_STYLE_LIST, !"{"#cOrange"}Назначить лидером:", global_string, !"Выбрать", !"Закрыть");
    return SetPlayerData(playerid, P_TARGETID, targetid);
}