(de wazap ()
   (sys "PYTHONUNBUFFERED" T)
   (when (setq *Wap (pipe (exec "yowsup-cli" "demos" "-l" (car *Wazap) "-y")))
      (unless (fork)
         (in *Wap
            (until (eof)
               (use (@L @D @Msg)
                  (let? Lst (line)
                     (when (head '`(chop "[connected]:") Lst)
                        (setq Lst (nth Lst 13)) )
                     (when
                        (match
                           '(@ "[" @L "(" @D ~(chop ")]:[") @ ~(chop "]\t ") @Msg)
                           Lst )
                        (let
                           (L (split @L "/" "@")
                              N (car (rassoc (car L) (cdr *Wazap)))
                              G (car (rassoc (cadr L) (cdr *Wazap))) )
                           (ifn N
                              (termlog RED "@" NONE " " @L " [" @D "] " @Msg)
                              (beep)
                              (termlog
                                 RED "@" NONE " " N
                                 (when G
                                    (pack "/" G) )
                                 " [" @D "] " @Msg ) ) ) ) ) ) ) )
         (bye) )
      (push1 '*Bye '(wazoff))
      (out *Wap (prinl "/L")) ) )

(de wazoff ()
   (when *Wap
      (out *Wap (prinl "/disconnect"))
      (call "killall" "yowsup-cli")
      (off *Wap) ) )